err.no Git - linux-2.6/blob - arch/x86_64/kernel/trampoline.S

   1 /*
   2  *
   3  *      Trampoline.S    Derived from Setup.S by Linus Torvalds
   4  *
   5  *      4 Jan 1997 Michael Chastain: changed to gnu as.
   6  *      15 Sept 2005 Eric Biederman: 64bit PIC support
   7  *
   8  *      Entry: CS:IP point to the start of our code, we are
   9  *      in real mode with no stack, but the rest of the
  10  *      trampoline page to make our stack and everything else
  11  *      is a mystery.
  12  *
  13  *      In fact we don't actually need a stack so we don't
  14  *      set one up.
  15  *
  16  *      On entry to trampoline_data, the processor is in real mode
  17  *      with 16-bit addressing and 16-bit data.  CS has some value
  18  *      and IP is zero.  Thus, data addresses need to be absolute
  19  *      (no relocation) and are taken with regard to r_base.
  20  *
  21  *      With the addition of trampoline_level4_pgt this code can
  22  *      now enter a 64bit kernel that lives at arbitrary 64bit
  23  *      physical addresses.
  24  *
  25  *      If you work on this file, check the object module with objdump
  26  *      --full-contents --reloc to make sure there are no relocation
  27  *      entries.
  28  */
  29
  30 #include <linux/linkage.h>
  31 #include <asm/pgtable.h>
  32 #include <asm/page.h>
  33 #include <asm/msr.h>
  34 #include <asm/segment.h>
  35
  36 .data
  37
  38 .code16
  39
  40 ENTRY(trampoline_data)
  41 r_base = .
  42         cli                     # We should be safe anyway
  43         wbinvd
  44         mov     %cs, %ax        # Code and data in the same place
  45         mov     %ax, %ds
  46         mov     %ax, %es
  47         mov     %ax, %ss
  48
  49
  50         movl    $0xA5A5A5A5, trampoline_data - r_base
  51                                 # write marker for master knows we're running
  52
  53                                         # Setup stack
  54         movw    $(trampoline_stack_end - r_base), %sp
  55
  56         call    verify_cpu              # Verify the cpu supports long mode
  57
  58         mov     %cs, %ax
  59         movzx   %ax, %esi               # Find the 32bit trampoline location
  60         shll    $4, %esi
  61
  62                                         # Fixup the vectors
  63         addl    %esi, startup_32_vector - r_base
  64         addl    %esi, startup_64_vector - r_base
  65         addl    %esi, tgdt + 2 - r_base # Fixup the gdt pointer
  66
  67         /*
  68          * GDT tables in non default location kernel can be beyond 16MB and
  69          * lgdt will not be able to load the address as in real mode default
  70          * operand size is 16bit. Use lgdtl instead to force operand size
  71          * to 32 bit.
  72          */
  73
  74         lidtl   tidt - r_base   # load idt with 0, 0
  75         lgdtl   tgdt - r_base   # load gdt with whatever is appropriate
  76
  77         xor     %ax, %ax
  78         inc     %ax             # protected mode (PE) bit
  79         lmsw    %ax             # into protected mode
  80
  81         # flush prefetch and jump to startup_32
  82         ljmpl   *(startup_32_vector - r_base)
  83
  84         .code32
  85         .balign 4
  86 startup_32:
  87         movl    $__KERNEL_DS, %eax      # Initialize the %ds segment register
  88         movl    %eax, %ds
  89
  90         xorl    %eax, %eax
  91         btsl    $5, %eax                # Enable PAE mode
  92         movl    %eax, %cr4
  93
  94                                         # Setup trampoline 4 level pagetables
  95         leal    (trampoline_level4_pgt - r_base)(%esi), %eax
  96         movl    %eax, %cr3
  97
  98         movl    $MSR_EFER, %ecx
  99         movl    $(1 << _EFER_LME), %eax # Enable Long Mode
 100         xorl    %edx, %edx
 101         wrmsr
 102
 103         xorl    %eax, %eax
 104         btsl    $31, %eax               # Enable paging and in turn activate Long Mode
 105         btsl    $0, %eax                # Enable protected mode
 106         movl    %eax, %cr0
 107
 108         /*
 109          * At this point we're in long mode but in 32bit compatibility mode
 110          * with EFER.LME = 1, CS.L = 0, CS.D = 1 (and in turn
 111          * EFER.LMA = 1). Now we want to jump in 64bit mode, to do that we use
 112          * the new gdt/idt that has __KERNEL_CS with CS.L = 1.
 113          */
 114         ljmp    *(startup_64_vector - r_base)(%esi)
 115
 116         .code64
 117         .balign 4
 118 startup_64:
 119         # Now jump into the kernel using virtual addresses
 120         movq    $secondary_startup_64, %rax
 121         jmp     *%rax
 122
 123         .code16
 124 verify_cpu:
 125         pushl   $0                      # Kill any dangerous flags
 126         popfl
 127
 128         /* minimum CPUID flags for x86-64 */
 129         /* see http://www.x86-64.org/lists/discuss/msg02971.html */
 130 #define REQUIRED_MASK1 ((1<<0)|(1<<3)|(1<<4)|(1<<5)|(1<<6)|(1<<8)|\
 131                            (1<<13)|(1<<15)|(1<<24)|(1<<25)|(1<<26))
 132 #define REQUIRED_MASK2 (1<<29)
 133
 134         pushfl                          # check for cpuid
 135         popl    %eax
 136         movl    %eax, %ebx
 137         xorl    $0x200000,%eax
 138         pushl   %eax
 139         popfl
 140         pushfl
 141         popl    %eax
 142         pushl   %ebx
 143         popfl
 144         cmpl    %eax, %ebx
 145         jz      no_longmode
 146
 147         xorl    %eax, %eax              # See if cpuid 1 is implemented
 148         cpuid
 149         cmpl    $0x1, %eax
 150         jb      no_longmode
 151
 152         movl    $0x01, %eax             # Does the cpu have what it takes?
 153         cpuid
 154         andl    $REQUIRED_MASK1, %edx
 155         xorl    $REQUIRED_MASK1, %edx
 156         jnz     no_longmode
 157
 158         movl    $0x80000000, %eax       # See if extended cpuid is implemented
 159         cpuid
 160         cmpl    $0x80000001, %eax
 161         jb      no_longmode
 162
 163         movl    $0x80000001, %eax       # Does the cpu have what it takes?
 164         cpuid
 165         andl    $REQUIRED_MASK2, %edx
 166         xorl    $REQUIRED_MASK2, %edx
 167         jnz     no_longmode
 168
 169         ret                             # The cpu supports long mode
 170
 171 no_longmode:
 172         hlt
 173         jmp no_longmode
 174
 175
 176         # Careful these need to be in the same 64K segment as the above;
 177 tidt:
 178         .word   0                       # idt limit = 0
 179         .word   0, 0                    # idt base = 0L
 180
 181         # Duplicate the global descriptor table
 182         # so the kernel can live anywhere
 183         .balign 4
 184 tgdt:
 185         .short  tgdt_end - tgdt         # gdt limit
 186         .long   tgdt - r_base
 187         .short 0
 188         .quad   0x00cf9b000000ffff      # __KERNEL32_CS
 189         .quad   0x00af9b000000ffff      # __KERNEL_CS
 190         .quad   0x00cf93000000ffff      # __KERNEL_DS
 191 tgdt_end:
 192
 193         .balign 4
 194 startup_32_vector:
 195         .long   startup_32 - r_base
 196         .word   __KERNEL32_CS, 0
 197
 198         .balign 4
 199 startup_64_vector:
 200         .long   startup_64 - r_base
 201         .word   __KERNEL_CS, 0
 202
 203 trampoline_stack:
 204         .org 0x1000
 205 trampoline_stack_end:
 206 ENTRY(trampoline_level4_pgt)
 207         .quad   level3_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
 208         .fill   510,8,0
 209         .quad   level3_kernel_pgt - __START_KERNEL_map + _KERNPG_TABLE
 210
 211 ENTRY(trampoline_end)