err.no Git - linux-2.6/blob - arch/x86_64/boot/setup.S

   1 /*
   2  *      setup.S         Copyright (C) 1991, 1992 Linus Torvalds
   3  *
   4  * setup.s is responsible for getting the system data from the BIOS,
   5  * and putting them into the appropriate places in system memory.
   6  * both setup.s and system has been loaded by the bootblock.
   7  *
   8  * This code asks the bios for memory/disk/other parameters, and
   9  * puts them in a "safe" place: 0x90000-0x901FF, ie where the
  10  * boot-block used to be. It is then up to the protected mode
  11  * system to read them from there before the area is overwritten
  12  * for buffer-blocks.
  13  *
  14  * Move PS/2 aux init code to psaux.c
  15  * (troyer@saifr00.cfsat.Honeywell.COM) 03Oct92
  16  *
  17  * some changes and additional features by Christoph Niemann,
  18  * March 1993/June 1994 (Christoph.Niemann@linux.org)
  19  *
  20  * add APM BIOS checking by Stephen Rothwell, May 1994
  21  * (sfr@canb.auug.org.au)
  22  *
  23  * High load stuff, initrd support and position independency
  24  * by Hans Lermen & Werner Almesberger, February 1996
  25  * <lermen@elserv.ffm.fgan.de>, <almesber@lrc.epfl.ch>
  26  *
  27  * Video handling moved to video.S by Martin Mares, March 1996
  28  * <mj@k332.feld.cvut.cz>
  29  *
  30  * Extended memory detection scheme retwiddled by orc@pell.chi.il.us (david
  31  * parsons) to avoid loadlin confusion, July 1997
  32  *
  33  * Transcribed from Intel (as86) -> AT&T (gas) by Chris Noe, May 1999.
  34  * <stiker@northlink.com>
  35  *
  36  * Fix to work around buggy BIOSes which don't use carry bit correctly
  37  * and/or report extended memory in CX/DX for e801h memory size detection
  38  * call.  As a result the kernel got wrong figures.  The int15/e801h docs
  39  * from Ralf Brown interrupt list seem to indicate AX/BX should be used
  40  * anyway.  So to avoid breaking many machines (presumably there was a reason
  41  * to orginally use CX/DX instead of AX/BX), we do a kludge to see
  42  * if CX/DX have been changed in the e801 call and if so use AX/BX .
  43  * Michael Miller, April 2001 <michaelm@mjmm.org>
  44  *
  45  * Added long mode checking and SSE force. March 2003, Andi Kleen.
  46  */
  47
  48 #include <asm/segment.h>
  49 #include <linux/utsrelease.h>
  50 #include <linux/compile.h>
  51 #include <asm/boot.h>
  52 #include <asm/e820.h>
  53 #include <asm/page.h>
  54
  55 /* Signature words to ensure LILO loaded us right */
  56 #define SIG1    0xAA55
  57 #define SIG2    0x5A5A
  58
  59 INITSEG  = DEF_INITSEG          # 0x9000, we move boot here, out of the way
  60 SYSSEG   = DEF_SYSSEG           # 0x1000, system loaded at 0x10000 (65536).
  61 SETUPSEG = DEF_SETUPSEG         # 0x9020, this is the current segment
  62                                 # ... and the former contents of CS
  63
  64 DELTA_INITSEG = SETUPSEG - INITSEG      # 0x0020
  65
  66 .code16
  67 .globl begtext, begdata, begbss, endtext, enddata, endbss
  68
  69 .text
  70 begtext:
  71 .data
  72 begdata:
  73 .bss
  74 begbss:
  75 .text
  76
  77 start:
  78         jmp     trampoline
  79
  80 # This is the setup header, and it must start at %cs:2 (old 0x9020:2)
  81
  82                 .ascii  "HdrS"          # header signature
  83                 .word   0x0205          # header version number (>= 0x0105)
  84                                         # or else old loadlin-1.5 will fail)
  85 realmode_swtch: .word   0, 0            # default_switch, SETUPSEG
  86 start_sys_seg:  .word   SYSSEG
  87                 .word   kernel_version  # pointing to kernel version string
  88                                         # above section of header is compatible
  89                                         # with loadlin-1.5 (header v1.5). Don't
  90                                         # change it.
  91
  92 type_of_loader: .byte   0               # = 0, old one (LILO, Loadlin,
  93                                         #      Bootlin, SYSLX, bootsect...)
  94                                         # See Documentation/i386/boot.txt for
  95                                         # assigned ids
  96
  97 # flags, unused bits must be zero (RFU) bit within loadflags
  98 loadflags:
  99 LOADED_HIGH     = 1                     # If set, the kernel is loaded high
 100 CAN_USE_HEAP    = 0x80                  # If set, the loader also has set
 101                                         # heap_end_ptr to tell how much
 102                                         # space behind setup.S can be used for
 103                                         # heap purposes.
 104                                         # Only the loader knows what is free
 105 #ifndef __BIG_KERNEL__
 106                 .byte   0
 107 #else
 108                 .byte   LOADED_HIGH
 109 #endif
 110
 111 setup_move_size: .word  0x8000          # size to move, when setup is not
 112                                         # loaded at 0x90000. We will move setup
 113                                         # to 0x90000 then just before jumping
 114                                         # into the kernel. However, only the
 115                                         # loader knows how much data behind
 116                                         # us also needs to be loaded.
 117
 118 code32_start:                           # here loaders can put a different
 119                                         # start address for 32-bit code.
 120 #ifndef __BIG_KERNEL__
 121                 .long   0x1000          #   0x1000 = default for zImage
 122 #else
 123                 .long   0x100000        # 0x100000 = default for big kernel
 124 #endif
 125
 126 ramdisk_image:  .long   0               # address of loaded ramdisk image
 127                                         # Here the loader puts the 32-bit
 128                                         # address where it loaded the image.
 129                                         # This only will be read by the kernel.
 130
 131 ramdisk_size:   .long   0               # its size in bytes
 132
 133 bootsect_kludge:
 134                 .long   0               # obsolete
 135
 136 heap_end_ptr:   .word   modelist+1024   # (Header version 0x0201 or later)
 137                                         # space from here (exclusive) down to
 138                                         # end of setup code can be used by setup
 139                                         # for local heap purposes.
 140
 141 pad1:           .word   0
 142 cmd_line_ptr:   .long 0                 # (Header version 0x0202 or later)
 143                                         # If nonzero, a 32-bit pointer
 144                                         # to the kernel command line.
 145                                         # The command line should be
 146                                         # located between the start of
 147                                         # setup and the end of low
 148                                         # memory (0xa0000), or it may
 149                                         # get overwritten before it
 150                                         # gets read.  If this field is
 151                                         # used, there is no longer
 152                                         # anything magical about the
 153                                         # 0x90000 segment; the setup
 154                                         # can be located anywhere in
 155                                         # low memory 0x10000 or higher.
 156
 157 ramdisk_max:    .long 0xffffffff
 158 kernel_alignment:  .long 0x200000       # physical addr alignment required for
 159                                         # protected mode relocatable kernel
 160 #ifdef CONFIG_RELOCATABLE
 161 relocatable_kernel:    .byte 1
 162 #else
 163 relocatable_kernel:    .byte 0
 164 #endif
 165 pad2:                  .byte 0
 166 pad3:                  .word 0
 167
 168 trampoline:     call    start_of_setup
 169                 .align 16
 170                                         # The offset at this point is 0x240
 171                 .space  (0xeff-0x240+1) # E820 & EDD space (ending at 0xeff)
 172 # End of setup header #####################################################
 173
 174 start_of_setup:
 175 # Bootlin depends on this being done early
 176         movw    $0x01500, %ax
 177         movb    $0x81, %dl
 178         int     $0x13
 179
 180 #ifdef SAFE_RESET_DISK_CONTROLLER
 181 # Reset the disk controller.
 182         movw    $0x0000, %ax
 183         movb    $0x80, %dl
 184         int     $0x13
 185 #endif
 186
 187 # Set %ds = %cs, we know that SETUPSEG = %cs at this point
 188         movw    %cs, %ax                # aka SETUPSEG
 189         movw    %ax, %ds
 190 # Check signature at end of setup
 191         cmpw    $SIG1, setup_sig1
 192         jne     bad_sig
 193
 194         cmpw    $SIG2, setup_sig2
 195         jne     bad_sig
 196
 197         jmp     good_sig1
 198
 199 # Routine to print asciiz string at ds:si
 200 prtstr:
 201         lodsb
 202         andb    %al, %al
 203         jz      fin
 204
 205         call    prtchr
 206         jmp     prtstr
 207
 208 fin:    ret
 209
 210 # Space printing
 211 prtsp2: call    prtspc          # Print double space
 212 prtspc: movb    $0x20, %al      # Print single space (note: fall-thru)
 213
 214 prtchr:
 215         pushw   %ax
 216         pushw   %cx
 217         movw    $0007,%bx
 218         movw    $0x01, %cx
 219         movb    $0x0e, %ah
 220         int     $0x10
 221         popw    %cx
 222         popw    %ax
 223         ret
 224
 225 beep:   movb    $0x07, %al
 226         jmp     prtchr
 227
 228 no_sig_mess: .string    "No setup signature found ..."
 229
 230 good_sig1:
 231         jmp     good_sig
 232
 233 # We now have to find the rest of the setup code/data
 234 bad_sig:
 235         movw    %cs, %ax                        # SETUPSEG
 236         subw    $DELTA_INITSEG, %ax             # INITSEG
 237         movw    %ax, %ds
 238         xorb    %bh, %bh
 239         movb    (497), %bl                      # get setup sect from bootsect
 240         subw    $4, %bx                         # LILO loads 4 sectors of setup
 241         shlw    $8, %bx                         # convert to words (1sect=2^8 words)
 242         movw    %bx, %cx
 243         shrw    $3, %bx                         # convert to segment
 244         addw    $SYSSEG, %bx
 245         movw    %bx, %cs:start_sys_seg
 246 # Move rest of setup code/data to here
 247         movw    $2048, %di                      # four sectors loaded by LILO
 248         subw    %si, %si
 249         movw    %cs, %ax                        # aka SETUPSEG
 250         movw    %ax, %es
 251         movw    $SYSSEG, %ax
 252         movw    %ax, %ds
 253         rep
 254         movsw
 255         movw    %cs, %ax                        # aka SETUPSEG
 256         movw    %ax, %ds
 257         cmpw    $SIG1, setup_sig1
 258         jne     no_sig
 259
 260         cmpw    $SIG2, setup_sig2
 261         jne     no_sig
 262
 263         jmp     good_sig
 264
 265 no_sig:
 266         lea     no_sig_mess, %si
 267         call    prtstr
 268
 269 no_sig_loop:
 270         jmp     no_sig_loop
 271
 272 good_sig:
 273         movw    %cs, %ax                        # aka SETUPSEG
 274         subw    $DELTA_INITSEG, %ax             # aka INITSEG
 275         movw    %ax, %ds
 276 # Check if an old loader tries to load a big-kernel
 277         testb   $LOADED_HIGH, %cs:loadflags     # Do we have a big kernel?
 278         jz      loader_ok                       # No, no danger for old loaders.
 279
 280         cmpb    $0, %cs:type_of_loader          # Do we have a loader that
 281                                                 # can deal with us?
 282         jnz     loader_ok                       # Yes, continue.
 283
 284         pushw   %cs                             # No, we have an old loader,
 285         popw    %ds                             # die.
 286         lea     loader_panic_mess, %si
 287         call    prtstr
 288
 289         jmp     no_sig_loop
 290
 291 loader_panic_mess: .string "Wrong loader, giving up..."
 292
 293 loader_ok:
 294         /* check for long mode. */
 295         /* we have to do this before the VESA setup, otherwise the user
 296            can't see the error message. */
 297
 298         pushw   %ds
 299         movw    %cs,%ax
 300         movw    %ax,%ds
 301
 302         call verify_cpu
 303         testl %eax,%eax
 304         jz sse_ok
 305
 306 no_longmode:
 307         call    beep
 308         lea     long_mode_panic,%si
 309         call    prtstr
 310 no_longmode_loop:
 311         jmp     no_longmode_loop
 312 long_mode_panic:
 313         .string "Your CPU does not support long mode. Use a 32bit distribution."
 314         .byte 0
 315
 316 #include "../kernel/verify_cpu.S"
 317 sse_ok:
 318         popw    %ds
 319
 320 # tell BIOS we want to go to long mode
 321         movl  $0xec00,%eax      # declare target operating mode
 322         movl  $2,%ebx           # long mode
 323         int $0x15
 324
 325 # Get memory size (extended mem, kB)
 326
 327         xorl    %eax, %eax
 328         movl    %eax, (0x1e0)
 329 #ifndef STANDARD_MEMORY_BIOS_CALL
 330         movb    %al, (E820NR)
 331 # Try three different memory detection schemes.  First, try
 332 # e820h, which lets us assemble a memory map, then try e801h,
 333 # which returns a 32-bit memory size, and finally 88h, which
 334 # returns 0-64m
 335
 336 # method E820H:
 337 # the memory map from hell.  e820h returns memory classified into
 338 # a whole bunch of different types, and allows memory holes and
 339 # everything.  We scan through this memory map and build a list
 340 # of the first 32 memory areas, which we return at [E820MAP].
 341 # This is documented at http://www.acpi.info/, in the ACPI 2.0 specification.
 342
 343 #define SMAP  0x534d4150
 344
 345 meme820:
 346         xorl    %ebx, %ebx                      # continuation counter
 347         movw    $E820MAP, %di                   # point into the whitelist
 348                                                 # so we can have the bios
 349                                                 # directly write into it.
 350
 351 jmpe820:
 352         movl    $0x0000e820, %eax               # e820, upper word zeroed
 353         movl    $SMAP, %edx                     # ascii 'SMAP'
 354         movl    $20, %ecx                       # size of the e820rec
 355         pushw   %ds                             # data record.
 356         popw    %es
 357         int     $0x15                           # make the call
 358         jc      bail820                         # fall to e801 if it fails
 359
 360         cmpl    $SMAP, %eax                     # check the return is `SMAP'
 361         jne     bail820                         # fall to e801 if it fails
 362
 363 #       cmpl    $1, 16(%di)                     # is this usable memory?
 364 #       jne     again820
 365
 366         # If this is usable memory, we save it by simply advancing %di by
 367         # sizeof(e820rec).
 368         #
 369 good820:
 370         movb    (E820NR), %al                   # up to 128 entries
 371         cmpb    $E820MAX, %al
 372         jae     bail820
 373
 374         incb    (E820NR)
 375         movw    %di, %ax
 376         addw    $20, %ax
 377         movw    %ax, %di
 378 again820:
 379         cmpl    $0, %ebx                        # check to see if
 380         jne     jmpe820                         # %ebx is set to EOF
 381 bail820:
 382
 383
 384 # method E801H:
 385 # memory size is in 1k chunksizes, to avoid confusing loadlin.
 386 # we store the 0xe801 memory size in a completely different place,
 387 # because it will most likely be longer than 16 bits.
 388 # (use 1e0 because that's what Larry Augustine uses in his
 389 # alternative new memory detection scheme, and it's sensible
 390 # to write everything into the same place.)
 391
 392 meme801:
 393         stc                                     # fix to work around buggy
 394         xorw    %cx,%cx                         # BIOSes which don't clear/set
 395         xorw    %dx,%dx                         # carry on pass/error of
 396                                                 # e801h memory size call
 397                                                 # or merely pass cx,dx though
 398                                                 # without changing them.
 399         movw    $0xe801, %ax
 400         int     $0x15
 401         jc      mem88
 402
 403         cmpw    $0x0, %cx                       # Kludge to handle BIOSes
 404         jne     e801usecxdx                     # which report their extended
 405         cmpw    $0x0, %dx                       # memory in AX/BX rather than
 406         jne     e801usecxdx                     # CX/DX.  The spec I have read
 407         movw    %ax, %cx                        # seems to indicate AX/BX
 408         movw    %bx, %dx                        # are more reasonable anyway...
 409
 410 e801usecxdx:
 411         andl    $0xffff, %edx                   # clear sign extend
 412         shll    $6, %edx                        # and go from 64k to 1k chunks
 413         movl    %edx, (0x1e0)                   # store extended memory size
 414         andl    $0xffff, %ecx                   # clear sign extend
 415         addl    %ecx, (0x1e0)                   # and add lower memory into
 416                                                 # total size.
 417
 418 # Ye Olde Traditional Methode.  Returns the memory size (up to 16mb or
 419 # 64mb, depending on the bios) in ax.
 420 mem88:
 421
 422 #endif
 423         movb    $0x88, %ah
 424         int     $0x15
 425         movw    %ax, (2)
 426
 427 # Set the keyboard repeat rate to the max
 428         movw    $0x0305, %ax
 429         xorw    %bx, %bx
 430         int     $0x16
 431
 432 # Check for video adapter and its parameters and allow the
 433 # user to browse video modes.
 434         call    video                           # NOTE: we need %ds pointing
 435                                                 # to bootsector
 436
 437 # Get hd0 data...
 438         xorw    %ax, %ax
 439         movw    %ax, %ds
 440         ldsw    (4 * 0x41), %si
 441         movw    %cs, %ax                        # aka SETUPSEG
 442         subw    $DELTA_INITSEG, %ax             # aka INITSEG
 443         pushw   %ax
 444         movw    %ax, %es
 445         movw    $0x0080, %di
 446         movw    $0x10, %cx
 447         pushw   %cx
 448         cld
 449         rep
 450         movsb
 451 # Get hd1 data...
 452         xorw    %ax, %ax
 453         movw    %ax, %ds
 454         ldsw    (4 * 0x46), %si
 455         popw    %cx
 456         popw    %es
 457         movw    $0x0090, %di
 458         rep
 459         movsb
 460 # Check that there IS a hd1 :-)
 461         movw    $0x01500, %ax
 462         movb    $0x81, %dl
 463         int     $0x13
 464         jc      no_disk1
 465
 466         cmpb    $3, %ah
 467         je      is_disk1
 468
 469 no_disk1:
 470         movw    %cs, %ax                        # aka SETUPSEG
 471         subw    $DELTA_INITSEG, %ax             # aka INITSEG
 472         movw    %ax, %es
 473         movw    $0x0090, %di
 474         movw    $0x10, %cx
 475         xorw    %ax, %ax
 476         cld
 477         rep
 478         stosb
 479 is_disk1:
 480
 481 # Check for PS/2 pointing device
 482         movw    %cs, %ax                        # aka SETUPSEG
 483         subw    $DELTA_INITSEG, %ax             # aka INITSEG
 484         movw    %ax, %ds
 485         movb    $0, (0x1ff)                     # default is no pointing device
 486         int     $0x11                           # int 0x11: equipment list
 487         testb   $0x04, %al                      # check if mouse installed
 488         jz      no_psmouse
 489
 490         movb    $0xAA, (0x1ff)                  # device present
 491 no_psmouse:
 492
 493 #include "../../i386/boot/edd.S"
 494
 495 # Now we want to move to protected mode ...
 496         cmpw    $0, %cs:realmode_swtch
 497         jz      rmodeswtch_normal
 498
 499         lcall   *%cs:realmode_swtch
 500
 501         jmp     rmodeswtch_end
 502
 503 rmodeswtch_normal:
 504         pushw   %cs
 505         call    default_switch
 506
 507 rmodeswtch_end:
 508 # we get the code32 start address and modify the below 'jmpi'
 509 # (loader may have changed it)
 510         movl    %cs:code32_start, %eax
 511         movl    %eax, %cs:code32
 512
 513 # Now we move the system to its rightful place ... but we check if we have a
 514 # big-kernel. In that case we *must* not move it ...
 515         testb   $LOADED_HIGH, %cs:loadflags
 516         jz      do_move0                        # .. then we have a normal low
 517                                                 # loaded zImage
 518                                                 # .. or else we have a high
 519                                                 # loaded bzImage
 520         jmp     end_move                        # ... and we skip moving
 521
 522 do_move0:
 523         movw    $0x100, %ax                     # start of destination segment
 524         movw    %cs, %bp                        # aka SETUPSEG
 525         subw    $DELTA_INITSEG, %bp             # aka INITSEG
 526         movw    %cs:start_sys_seg, %bx          # start of source segment
 527         cld
 528 do_move:
 529         movw    %ax, %es                        # destination segment
 530         incb    %ah                             # instead of add ax,#0x100
 531         movw    %bx, %ds                        # source segment
 532         addw    $0x100, %bx
 533         subw    %di, %di
 534         subw    %si, %si
 535         movw    $0x800, %cx
 536         rep
 537         movsw
 538         cmpw    %bp, %bx                        # assume start_sys_seg > 0x200,
 539                                                 # so we will perhaps read one
 540                                                 # page more than needed, but
 541                                                 # never overwrite INITSEG
 542                                                 # because destination is a
 543                                                 # minimum one page below source
 544         jb      do_move
 545
 546 end_move:
 547 # then we load the segment descriptors
 548         movw    %cs, %ax                        # aka SETUPSEG
 549         movw    %ax, %ds
 550
 551 # Check whether we need to be downward compatible with version <=201
 552         cmpl    $0, cmd_line_ptr
 553         jne     end_move_self           # loader uses version >=202 features
 554         cmpb    $0x20, type_of_loader
 555         je      end_move_self           # bootsect loader, we know of it
 556
 557 # Boot loader doesnt support boot protocol version 2.02.
 558 # If we have our code not at 0x90000, we need to move it there now.
 559 # We also then need to move the params behind it (commandline)
 560 # Because we would overwrite the code on the current IP, we move
 561 # it in two steps, jumping high after the first one.
 562         movw    %cs, %ax
 563         cmpw    $SETUPSEG, %ax
 564         je      end_move_self
 565
 566         cli                                     # make sure we really have
 567                                                 # interrupts disabled !
 568                                                 # because after this the stack
 569                                                 # should not be used
 570         subw    $DELTA_INITSEG, %ax             # aka INITSEG
 571         movw    %ss, %dx
 572         cmpw    %ax, %dx
 573         jb      move_self_1
 574
 575         addw    $INITSEG, %dx
 576         subw    %ax, %dx                        # this will go into %ss after
 577                                                 # the move
 578 move_self_1:
 579         movw    %ax, %ds
 580         movw    $INITSEG, %ax                   # real INITSEG
 581         movw    %ax, %es
 582         movw    %cs:setup_move_size, %cx
 583         std                                     # we have to move up, so we use
 584                                                 # direction down because the
 585                                                 # areas may overlap
 586         movw    %cx, %di
 587         decw    %di
 588         movw    %di, %si
 589         subw    $move_self_here+0x200, %cx
 590         rep
 591         movsb
 592         ljmp    $SETUPSEG, $move_self_here
 593
 594 move_self_here:
 595         movw    $move_self_here+0x200, %cx
 596         rep
 597         movsb
 598         movw    $SETUPSEG, %ax
 599         movw    %ax, %ds
 600         movw    %dx, %ss
 601 end_move_self:                                  # now we are at the right place
 602         lidt    idt_48                          # load idt with 0,0
 603         xorl    %eax, %eax                      # Compute gdt_base
 604         movw    %ds, %ax                        # (Convert %ds:gdt to a linear ptr)
 605         shll    $4, %eax
 606         addl    $gdt, %eax
 607         movl    %eax, (gdt_48+2)
 608         lgdt    gdt_48                          # load gdt with whatever is
 609                                                 # appropriate
 610
 611 # that was painless, now we enable a20
 612         call    empty_8042
 613
 614         movb    $0xD1, %al                      # command write
 615         outb    %al, $0x64
 616         call    empty_8042
 617
 618         movb    $0xDF, %al                      # A20 on
 619         outb    %al, $0x60
 620         call    empty_8042
 621
 622 #
 623 #       You must preserve the other bits here. Otherwise embarrasing things
 624 #       like laptops powering off on boot happen. Corrected version by Kira
 625 #       Brown from Linux 2.2
 626 #
 627         inb     $0x92, %al                      #
 628         orb     $02, %al                        # "fast A20" version
 629         outb    %al, $0x92                      # some chips have only this
 630
 631 # wait until a20 really *is* enabled; it can take a fair amount of
 632 # time on certain systems; Toshiba Tecras are known to have this
 633 # problem.  The memory location used here (0x200) is the int 0x80
 634 # vector, which should be safe to use.
 635
 636         xorw    %ax, %ax                        # segment 0x0000
 637         movw    %ax, %fs
 638         decw    %ax                             # segment 0xffff (HMA)
 639         movw    %ax, %gs
 640 a20_wait:
 641         incw    %ax                             # unused memory location <0xfff0
 642         movw    %ax, %fs:(0x200)                # we use the "int 0x80" vector
 643         cmpw    %gs:(0x210), %ax                # and its corresponding HMA addr
 644         je      a20_wait                        # loop until no longer aliased
 645
 646 # make sure any possible coprocessor is properly reset..
 647         xorw    %ax, %ax
 648         outb    %al, $0xf0
 649         call    delay
 650
 651         outb    %al, $0xf1
 652         call    delay
 653
 654 # well, that went ok, I hope. Now we mask all interrupts - the rest
 655 # is done in init_IRQ().
 656         movb    $0xFF, %al                      # mask all interrupts for now
 657         outb    %al, $0xA1
 658         call    delay
 659
 660         movb    $0xFB, %al                      # mask all irq's but irq2 which
 661         outb    %al, $0x21                      # is cascaded
 662
 663 # Well, that certainly wasn't fun :-(. Hopefully it works, and we don't
 664 # need no steenking BIOS anyway (except for the initial loading :-).
 665 # The BIOS-routine wants lots of unnecessary data, and it's less
 666 # "interesting" anyway. This is how REAL programmers do it.
 667 #
 668 # Well, now's the time to actually move into protected mode. To make
 669 # things as simple as possible, we do no register set-up or anything,
 670 # we let the gnu-compiled 32-bit programs do that. We just jump to
 671 # absolute address 0x1000 (or the loader supplied one),
 672 # in 32-bit protected mode.
 673 #
 674 # Note that the short jump isn't strictly needed, although there are
 675 # reasons why it might be a good idea. It won't hurt in any case.
 676         movw    $1, %ax                         # protected mode (PE) bit
 677         lmsw    %ax                             # This is it!
 678         jmp     flush_instr
 679
 680 flush_instr:
 681         xorw    %bx, %bx                        # Flag to indicate a boot
 682         xorl    %esi, %esi                      # Pointer to real-mode code
 683         movw    %cs, %si
 684         subw    $DELTA_INITSEG, %si
 685         shll    $4, %esi                        # Convert to 32-bit pointer
 686 # NOTE: For high loaded big kernels we need a
 687 #       jmpi    0x100000,__KERNEL_CS
 688 #
 689 #       but we yet haven't reloaded the CS register, so the default size
 690 #       of the target offset still is 16 bit.
 691 #       However, using an operand prefix (0x66), the CPU will properly
 692 #       take our 48 bit far pointer. (INTeL 80386 Programmer's Reference
 693 #       Manual, Mixing 16-bit and 32-bit code, page 16-6)
 694
 695         .byte 0x66, 0xea                        # prefix + jmpi-opcode
 696 code32: .long   0x1000                          # will be set to 0x100000
 697                                                 # for big kernels
 698         .word   __KERNEL_CS
 699
 700 # Here's a bunch of information about your current kernel..
 701 kernel_version: .ascii  UTS_RELEASE
 702                 .ascii  " ("
 703                 .ascii  LINUX_COMPILE_BY
 704                 .ascii  "@"
 705                 .ascii  LINUX_COMPILE_HOST
 706                 .ascii  ") "
 707                 .ascii  UTS_VERSION
 708                 .byte   0
 709
 710 # This is the default real mode switch routine.
 711 # to be called just before protected mode transition
 712 default_switch:
 713         cli                                     # no interrupts allowed !
 714         movb    $0x80, %al                      # disable NMI for bootup
 715                                                 # sequence
 716         outb    %al, $0x70
 717         lret
 718
 719
 720 # This routine checks that the keyboard command queue is empty
 721 # (after emptying the output buffers)
 722 #
 723 # Some machines have delusions that the keyboard buffer is always full
 724 # with no keyboard attached...
 725 #
 726 # If there is no keyboard controller, we will usually get 0xff
 727 # to all the reads.  With each IO taking a microsecond and
 728 # a timeout of 100,000 iterations, this can take about half a
 729 # second ("delay" == outb to port 0x80). That should be ok,
 730 # and should also be plenty of time for a real keyboard controller
 731 # to empty.
 732 #
 733
 734 empty_8042:
 735         pushl   %ecx
 736         movl    $100000, %ecx
 737
 738 empty_8042_loop:
 739         decl    %ecx
 740         jz      empty_8042_end_loop
 741
 742         call    delay
 743
 744         inb     $0x64, %al                      # 8042 status port
 745         testb   $1, %al                         # output buffer?
 746         jz      no_output
 747
 748         call    delay
 749         inb     $0x60, %al                      # read it
 750         jmp     empty_8042_loop
 751
 752 no_output:
 753         testb   $2, %al                         # is input buffer full?
 754         jnz     empty_8042_loop                 # yes - loop
 755 empty_8042_end_loop:
 756         popl    %ecx
 757         ret
 758
 759 # Read the cmos clock. Return the seconds in al
 760 gettime:
 761         pushw   %cx
 762         movb    $0x02, %ah
 763         int     $0x1a
 764         movb    %dh, %al                        # %dh contains the seconds
 765         andb    $0x0f, %al
 766         movb    %dh, %ah
 767         movb    $0x04, %cl
 768         shrb    %cl, %ah
 769         aad
 770         popw    %cx
 771         ret
 772
 773 # Delay is needed after doing I/O
 774 delay:
 775         outb    %al,$0x80
 776         ret
 777
 778 # Descriptor tables
 779 gdt:
 780         .word   0, 0, 0, 0                      # dummy
 781
 782         .word   0, 0, 0, 0                      # unused
 783
 784         .word   0xFFFF                          # 4Gb - (0x100000*0x1000 = 4Gb)
 785         .word   0                               # base address = 0
 786         .word   0x9A00                          # code read/exec
 787         .word   0x00CF                          # granularity = 4096, 386
 788                                                 #  (+5th nibble of limit)
 789
 790         .word   0xFFFF                          # 4Gb - (0x100000*0x1000 = 4Gb)
 791         .word   0                               # base address = 0
 792         .word   0x9200                          # data read/write
 793         .word   0x00CF                          # granularity = 4096, 386
 794                                                 #  (+5th nibble of limit)
 795 gdt_end:
 796 idt_48:
 797         .word   0                               # idt limit = 0
 798         .word   0, 0                            # idt base = 0L
 799 gdt_48:
 800         .word   gdt_end-gdt-1                   # gdt limit
 801         .word   0, 0                            # gdt base (filled in later)
 802
 803 # Include video setup & detection code
 804
 805 #include "video.S"
 806
 807 # Setup signature -- must be last
 808 setup_sig1:     .word   SIG1
 809 setup_sig2:     .word   SIG2
 810
 811 # After this point, there is some free space which is used by the video mode
 812 # handling code to store the temporary mode table (not used by the kernel).
 813
 814 modelist:
 815
 816 .text
 817 endtext:
 818 .data
 819 enddata:
 820 .bss
 821 endbss: