err.no Git - linux-2.6/blob - arch/x86/kernel/vmlinux_64.lds.S

   1 /* ld script to make x86-64 Linux kernel
   2  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
   3  */
   4
   5 #define LOAD_OFFSET __START_KERNEL_map
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/page.h>
   9
  10 #undef i386     /* in case the preprocessor is a 32bit one */
  11
  12 OUTPUT_FORMAT("elf64-x86-64", "elf64-x86-64", "elf64-x86-64")
  13 OUTPUT_ARCH(i386:x86-64)
  14 ENTRY(phys_startup_64)
  15 jiffies_64 = jiffies;
  16 _proxy_pda = 1;
  17 PHDRS {
  18         text PT_LOAD FLAGS(5);  /* R_E */
  19         data PT_LOAD FLAGS(7);  /* RWE */
  20         user PT_LOAD FLAGS(7);  /* RWE */
  21         data.init PT_LOAD FLAGS(7);     /* RWE */
  22         note PT_NOTE FLAGS(0);  /* ___ */
  23 }
  24 SECTIONS
  25 {
  26   . = __START_KERNEL;
  27   phys_startup_64 = startup_64 - LOAD_OFFSET;
  28   _text = .;                    /* Text and read-only data */
  29   .text :  AT(ADDR(.text) - LOAD_OFFSET) {
  30         /* First the code that has to be first for bootstrapping */
  31         *(.text.head)
  32         _stext = .;
  33         /* Then the rest */
  34         TEXT_TEXT
  35         SCHED_TEXT
  36         LOCK_TEXT
  37         KPROBES_TEXT
  38         *(.fixup)
  39         *(.gnu.warning)
  40         _etext = .;             /* End of text section */
  41   } :text = 0x9090
  42
  43   NOTES :text :note
  44
  45   . = ALIGN(16);                /* Exception table */
  46   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) {
  47         __start___ex_table = .;
  48          *(__ex_table)
  49         __stop___ex_table = .;
  50   } :text = 0x9090
  51
  52   RODATA
  53
  54   . = ALIGN(PAGE_SIZE);         /* Align data segment to page size boundary */
  55                                 /* Data */
  56   .data : AT(ADDR(.data) - LOAD_OFFSET) {
  57         DATA_DATA
  58         CONSTRUCTORS
  59         } :data
  60
  61   _edata = .;                   /* End of data section */
  62
  63   . = ALIGN(PAGE_SIZE);
  64   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  65   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) {
  66         *(.data.cacheline_aligned)
  67   }
  68   . = ALIGN(CONFIG_X86_INTERNODE_CACHE_BYTES);
  69   .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET) {
  70         *(.data.read_mostly)
  71   }
  72
  73 #define VSYSCALL_ADDR (-10*1024*1024)
  74 #define VSYSCALL_PHYS_ADDR ((LOADADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  75 #define VSYSCALL_VIRT_ADDR ((ADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  76
  77 #define VLOAD_OFFSET (VSYSCALL_ADDR - VSYSCALL_PHYS_ADDR)
  78 #define VLOAD(x) (ADDR(x) - VLOAD_OFFSET)
  79
  80 #define VVIRT_OFFSET (VSYSCALL_ADDR - VSYSCALL_VIRT_ADDR)
  81 #define VVIRT(x) (ADDR(x) - VVIRT_OFFSET)
  82
  83   . = VSYSCALL_ADDR;
  84   .vsyscall_0 :  AT(VSYSCALL_PHYS_ADDR) { *(.vsyscall_0) } :user
  85   __vsyscall_0 = VSYSCALL_VIRT_ADDR;
  86
  87   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  88   .vsyscall_fn : AT(VLOAD(.vsyscall_fn)) { *(.vsyscall_fn) }
  89   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  90   .vsyscall_gtod_data : AT(VLOAD(.vsyscall_gtod_data))
  91                 { *(.vsyscall_gtod_data) }
  92   vsyscall_gtod_data = VVIRT(.vsyscall_gtod_data);
  93   .vsyscall_clock : AT(VLOAD(.vsyscall_clock))
  94                 { *(.vsyscall_clock) }
  95   vsyscall_clock = VVIRT(.vsyscall_clock);
  96
  97
  98   .vsyscall_1 ADDR(.vsyscall_0) + 1024: AT(VLOAD(.vsyscall_1))
  99                 { *(.vsyscall_1) }
 100   .vsyscall_2 ADDR(.vsyscall_0) + 2048: AT(VLOAD(.vsyscall_2))
 101                 { *(.vsyscall_2) }
 102
 103   .vgetcpu_mode : AT(VLOAD(.vgetcpu_mode)) { *(.vgetcpu_mode) }
 104   vgetcpu_mode = VVIRT(.vgetcpu_mode);
 105
 106   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 107   .jiffies : AT(VLOAD(.jiffies)) { *(.jiffies) }
 108   jiffies = VVIRT(.jiffies);
 109
 110   .vsyscall_3 ADDR(.vsyscall_0) + 3072: AT(VLOAD(.vsyscall_3))
 111                 { *(.vsyscall_3) }
 112
 113   . = VSYSCALL_VIRT_ADDR + PAGE_SIZE;
 114
 115 #undef VSYSCALL_ADDR
 116 #undef VSYSCALL_PHYS_ADDR
 117 #undef VSYSCALL_VIRT_ADDR
 118 #undef VLOAD_OFFSET
 119 #undef VLOAD
 120 #undef VVIRT_OFFSET
 121 #undef VVIRT
 122
 123   . = ALIGN(THREAD_SIZE);       /* init_task */
 124   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) {
 125         *(.data.init_task)
 126   }:data.init
 127
 128   . = ALIGN(PAGE_SIZE);
 129   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) {
 130         *(.data.page_aligned)
 131   }
 132
 133   /* might get freed after init */
 134   . = ALIGN(PAGE_SIZE);
 135   __smp_alt_begin = .;
 136   __smp_locks = .;
 137   .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 138         *(.smp_locks)
 139   }
 140   __smp_locks_end = .;
 141   . = ALIGN(PAGE_SIZE);
 142   __smp_alt_end = .;
 143
 144   . = ALIGN(PAGE_SIZE);         /* Init code and data */
 145   __init_begin = .;
 146   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
 147         _sinittext = .;
 148         INIT_TEXT
 149         _einittext = .;
 150   }
 151   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {
 152         __initdata_begin = .;
 153         INIT_DATA
 154         __initdata_end = .;
 155    }
 156
 157   . = ALIGN(16);
 158   __setup_start = .;
 159   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) { *(.init.setup) }
 160   __setup_end = .;
 161   __initcall_start = .;
 162   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 163         INITCALLS
 164   }
 165   __initcall_end = .;
 166   __con_initcall_start = .;
 167   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 168         *(.con_initcall.init)
 169   }
 170   __con_initcall_end = .;
 171   . = ALIGN(16);
 172   __x86cpuvendor_start = .;
 173   .x86cpuvendor.init : AT(ADDR(.x86cpuvendor.init) - LOAD_OFFSET) {
 174         *(.x86cpuvendor.init)
 175   }
 176   __x86cpuvendor_end = .;
 177   SECURITY_INIT
 178
 179   . = ALIGN(8);
 180   .parainstructions : AT(ADDR(.parainstructions) - LOAD_OFFSET) {
 181   __parainstructions = .;
 182        *(.parainstructions)
 183   __parainstructions_end = .;
 184   }
 185
 186   . = ALIGN(8);
 187   __alt_instructions = .;
 188   .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 189         *(.altinstructions)
 190   }
 191   __alt_instructions_end = .;
 192   .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 193         *(.altinstr_replacement)
 194   }
 195   /* .exit.text is discard at runtime, not link time, to deal with references
 196      from .altinstructions and .eh_frame */
 197   .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
 198         EXIT_TEXT
 199   }
 200   .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
 201         EXIT_DATA
 202   }
 203
 204 #ifdef CONFIG_BLK_DEV_INITRD
 205   . = ALIGN(PAGE_SIZE);
 206   __initramfs_start = .;
 207   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) { *(.init.ramfs) }
 208   __initramfs_end = .;
 209 #endif
 210
 211   PERCPU(PAGE_SIZE)
 212
 213   . = ALIGN(PAGE_SIZE);
 214   __init_end = .;
 215
 216   . = ALIGN(PAGE_SIZE);
 217   __nosave_begin = .;
 218   .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { *(.data.nosave) }
 219   . = ALIGN(PAGE_SIZE);
 220   __nosave_end = .;
 221
 222   __bss_start = .;              /* BSS */
 223   .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 224         *(.bss.page_aligned)
 225         *(.bss)
 226         }
 227   __bss_stop = .;
 228
 229   _end = . ;
 230
 231   /* Sections to be discarded */
 232   /DISCARD/ : {
 233         *(.exitcall.exit)
 234         *(.eh_frame)
 235         }
 236
 237   STABS_DEBUG
 238
 239   DWARF_DEBUG
 240 }
 241
 242 /*
 243  * Build-time check on the image size:
 244  */
 245 ASSERT((_end - _text <= KERNEL_IMAGE_SIZE),
 246         "kernel image bigger than KERNEL_IMAGE_SIZE")