err.no Git - linux-2.6/blob - arch/x86/kernel/entry_32.S

   1 /*
   2  *  linux/arch/i386/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  */
   6
   7 /*
   8  * entry.S contains the system-call and fault low-level handling routines.
   9  * This also contains the timer-interrupt handler, as well as all interrupts
  10  * and faults that can result in a task-switch.
  11  *
  12  * NOTE: This code handles signal-recognition, which happens every time
  13  * after a timer-interrupt and after each system call.
  14  *
  15  * I changed all the .align's to 4 (16 byte alignment), as that's faster
  16  * on a 486.
  17  *
  18  * Stack layout in 'syscall_exit':
  19  *      ptrace needs to have all regs on the stack.
  20  *      if the order here is changed, it needs to be
  21  *      updated in fork.c:copy_process, signal.c:do_signal,
  22  *      ptrace.c and ptrace.h
  23  *
  24  *       0(%esp) - %ebx
  25  *       4(%esp) - %ecx
  26  *       8(%esp) - %edx
  27  *       C(%esp) - %esi
  28  *      10(%esp) - %edi
  29  *      14(%esp) - %ebp
  30  *      18(%esp) - %eax
  31  *      1C(%esp) - %ds
  32  *      20(%esp) - %es
  33  *      24(%esp) - %fs
  34  *      28(%esp) - orig_eax
  35  *      2C(%esp) - %eip
  36  *      30(%esp) - %cs
  37  *      34(%esp) - %eflags
  38  *      38(%esp) - %oldesp
  39  *      3C(%esp) - %oldss
  40  *
  41  * "current" is in register %ebx during any slow entries.
  42  */
  43
  44 #include <linux/linkage.h>
  45 #include <asm/thread_info.h>
  46 #include <asm/irqflags.h>
  47 #include <asm/errno.h>
  48 #include <asm/segment.h>
  49 #include <asm/smp.h>
  50 #include <asm/page.h>
  51 #include <asm/desc.h>
  52 #include <asm/percpu.h>
  53 #include <asm/dwarf2.h>
  54 #include "irq_vectors.h"
  55
  56 /*
  57  * We use macros for low-level operations which need to be overridden
  58  * for paravirtualization.  The following will never clobber any registers:
  59  *   INTERRUPT_RETURN (aka. "iret")
  60  *   GET_CR0_INTO_EAX (aka. "movl %cr0, %eax")
  61  *   ENABLE_INTERRUPTS_SYSCALL_RET (aka "sti; sysexit").
  62  *
  63  * For DISABLE_INTERRUPTS/ENABLE_INTERRUPTS (aka "cli"/"sti"), you must
  64  * specify what registers can be overwritten (CLBR_NONE, CLBR_EAX/EDX/ECX/ANY).
  65  * Allowing a register to be clobbered can shrink the paravirt replacement
  66  * enough to patch inline, increasing performance.
  67  */
  68
  69 #define nr_syscalls ((syscall_table_size)/4)
  70
  71 CF_MASK         = 0x00000001
  72 TF_MASK         = 0x00000100
  73 IF_MASK         = 0x00000200
  74 DF_MASK         = 0x00000400
  75 NT_MASK         = 0x00004000
  76 VM_MASK         = 0x00020000
  77
  78 #ifdef CONFIG_PREEMPT
  79 #define preempt_stop(clobbers)  DISABLE_INTERRUPTS(clobbers); TRACE_IRQS_OFF
  80 #else
  81 #define preempt_stop(clobbers)
  82 #define resume_kernel           restore_nocheck
  83 #endif
  84
  85 .macro TRACE_IRQS_IRET
  86 #ifdef CONFIG_TRACE_IRQFLAGS
  87         testl $IF_MASK,PT_EFLAGS(%esp)     # interrupts off?
  88         jz 1f
  89         TRACE_IRQS_ON
  90 1:
  91 #endif
  92 .endm
  93
  94 #ifdef CONFIG_VM86
  95 #define resume_userspace_sig    check_userspace
  96 #else
  97 #define resume_userspace_sig    resume_userspace
  98 #endif
  99
 100 #define SAVE_ALL \
 101         cld; \
 102         pushl %fs; \
 103         CFI_ADJUST_CFA_OFFSET 4;\
 104         /*CFI_REL_OFFSET fs, 0;*/\
 105         pushl %es; \
 106         CFI_ADJUST_CFA_OFFSET 4;\
 107         /*CFI_REL_OFFSET es, 0;*/\
 108         pushl %ds; \
 109         CFI_ADJUST_CFA_OFFSET 4;\
 110         /*CFI_REL_OFFSET ds, 0;*/\
 111         pushl %eax; \
 112         CFI_ADJUST_CFA_OFFSET 4;\
 113         CFI_REL_OFFSET eax, 0;\
 114         pushl %ebp; \
 115         CFI_ADJUST_CFA_OFFSET 4;\
 116         CFI_REL_OFFSET ebp, 0;\
 117         pushl %edi; \
 118         CFI_ADJUST_CFA_OFFSET 4;\
 119         CFI_REL_OFFSET edi, 0;\
 120         pushl %esi; \
 121         CFI_ADJUST_CFA_OFFSET 4;\
 122         CFI_REL_OFFSET esi, 0;\
 123         pushl %edx; \
 124         CFI_ADJUST_CFA_OFFSET 4;\
 125         CFI_REL_OFFSET edx, 0;\
 126         pushl %ecx; \
 127         CFI_ADJUST_CFA_OFFSET 4;\
 128         CFI_REL_OFFSET ecx, 0;\
 129         pushl %ebx; \
 130         CFI_ADJUST_CFA_OFFSET 4;\
 131         CFI_REL_OFFSET ebx, 0;\
 132         movl $(__USER_DS), %edx; \
 133         movl %edx, %ds; \
 134         movl %edx, %es; \
 135         movl $(__KERNEL_PERCPU), %edx; \
 136         movl %edx, %fs
 137
 138 #define RESTORE_INT_REGS \
 139         popl %ebx;      \
 140         CFI_ADJUST_CFA_OFFSET -4;\
 141         CFI_RESTORE ebx;\
 142         popl %ecx;      \
 143         CFI_ADJUST_CFA_OFFSET -4;\
 144         CFI_RESTORE ecx;\
 145         popl %edx;      \
 146         CFI_ADJUST_CFA_OFFSET -4;\
 147         CFI_RESTORE edx;\
 148         popl %esi;      \
 149         CFI_ADJUST_CFA_OFFSET -4;\
 150         CFI_RESTORE esi;\
 151         popl %edi;      \
 152         CFI_ADJUST_CFA_OFFSET -4;\
 153         CFI_RESTORE edi;\
 154         popl %ebp;      \
 155         CFI_ADJUST_CFA_OFFSET -4;\
 156         CFI_RESTORE ebp;\
 157         popl %eax;      \
 158         CFI_ADJUST_CFA_OFFSET -4;\
 159         CFI_RESTORE eax
 160
 161 #define RESTORE_REGS    \
 162         RESTORE_INT_REGS; \
 163 1:      popl %ds;       \
 164         CFI_ADJUST_CFA_OFFSET -4;\
 165         /*CFI_RESTORE ds;*/\
 166 2:      popl %es;       \
 167         CFI_ADJUST_CFA_OFFSET -4;\
 168         /*CFI_RESTORE es;*/\
 169 3:      popl %fs;       \
 170         CFI_ADJUST_CFA_OFFSET -4;\
 171         /*CFI_RESTORE fs;*/\
 172 .pushsection .fixup,"ax";       \
 173 4:      movl $0,(%esp); \
 174         jmp 1b;         \
 175 5:      movl $0,(%esp); \
 176         jmp 2b;         \
 177 6:      movl $0,(%esp); \
 178         jmp 3b;         \
 179 .section __ex_table,"a";\
 180         .align 4;       \
 181         .long 1b,4b;    \
 182         .long 2b,5b;    \
 183         .long 3b,6b;    \
 184 .popsection
 185
 186 #define RING0_INT_FRAME \
 187         CFI_STARTPROC simple;\
 188         CFI_SIGNAL_FRAME;\
 189         CFI_DEF_CFA esp, 3*4;\
 190         /*CFI_OFFSET cs, -2*4;*/\
 191         CFI_OFFSET eip, -3*4
 192
 193 #define RING0_EC_FRAME \
 194         CFI_STARTPROC simple;\
 195         CFI_SIGNAL_FRAME;\
 196         CFI_DEF_CFA esp, 4*4;\
 197         /*CFI_OFFSET cs, -2*4;*/\
 198         CFI_OFFSET eip, -3*4
 199
 200 #define RING0_PTREGS_FRAME \
 201         CFI_STARTPROC simple;\
 202         CFI_SIGNAL_FRAME;\
 203         CFI_DEF_CFA esp, PT_OLDESP-PT_EBX;\
 204         /*CFI_OFFSET cs, PT_CS-PT_OLDESP;*/\
 205         CFI_OFFSET eip, PT_EIP-PT_OLDESP;\
 206         /*CFI_OFFSET es, PT_ES-PT_OLDESP;*/\
 207         /*CFI_OFFSET ds, PT_DS-PT_OLDESP;*/\
 208         CFI_OFFSET eax, PT_EAX-PT_OLDESP;\
 209         CFI_OFFSET ebp, PT_EBP-PT_OLDESP;\
 210         CFI_OFFSET edi, PT_EDI-PT_OLDESP;\
 211         CFI_OFFSET esi, PT_ESI-PT_OLDESP;\
 212         CFI_OFFSET edx, PT_EDX-PT_OLDESP;\
 213         CFI_OFFSET ecx, PT_ECX-PT_OLDESP;\
 214         CFI_OFFSET ebx, PT_EBX-PT_OLDESP
 215
 216 ENTRY(ret_from_fork)
 217         CFI_STARTPROC
 218         pushl %eax
 219         CFI_ADJUST_CFA_OFFSET 4
 220         call schedule_tail
 221         GET_THREAD_INFO(%ebp)
 222         popl %eax
 223         CFI_ADJUST_CFA_OFFSET -4
 224         pushl $0x0202                   # Reset kernel eflags
 225         CFI_ADJUST_CFA_OFFSET 4
 226         popfl
 227         CFI_ADJUST_CFA_OFFSET -4
 228         jmp syscall_exit
 229         CFI_ENDPROC
 230 END(ret_from_fork)
 231
 232 /*
 233  * Return to user mode is not as complex as all this looks,
 234  * but we want the default path for a system call return to
 235  * go as quickly as possible which is why some of this is
 236  * less clear than it otherwise should be.
 237  */
 238
 239         # userspace resumption stub bypassing syscall exit tracing
 240         ALIGN
 241         RING0_PTREGS_FRAME
 242 ret_from_exception:
 243         preempt_stop(CLBR_ANY)
 244 ret_from_intr:
 245         GET_THREAD_INFO(%ebp)
 246 check_userspace:
 247         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS and CS
 248         movb PT_CS(%esp), %al
 249         andl $(VM_MASK | SEGMENT_RPL_MASK), %eax
 250         cmpl $USER_RPL, %eax
 251         jb resume_kernel                # not returning to v8086 or userspace
 252
 253 ENTRY(resume_userspace)
 254         LOCKDEP_SYS_EXIT
 255         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 256                                         # setting need_resched or sigpending
 257                                         # between sampling and the iret
 258         movl TI_flags(%ebp), %ecx
 259         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done on
 260                                         # int/exception return?
 261         jne work_pending
 262         jmp restore_all
 263 END(ret_from_exception)
 264
 265 #ifdef CONFIG_PREEMPT
 266 ENTRY(resume_kernel)
 267         DISABLE_INTERRUPTS(CLBR_ANY)
 268         cmpl $0,TI_preempt_count(%ebp)  # non-zero preempt_count ?
 269         jnz restore_nocheck
 270 need_resched:
 271         movl TI_flags(%ebp), %ecx       # need_resched set ?
 272         testb $_TIF_NEED_RESCHED, %cl
 273         jz restore_all
 274         testl $IF_MASK,PT_EFLAGS(%esp)  # interrupts off (exception path) ?
 275         jz restore_all
 276         call preempt_schedule_irq
 277         jmp need_resched
 278 END(resume_kernel)
 279 #endif
 280         CFI_ENDPROC
 281
 282 /* SYSENTER_RETURN points to after the "sysenter" instruction in
 283    the vsyscall page.  See vsyscall-sysentry.S, which defines the symbol.  */
 284
 285         # sysenter call handler stub
 286 ENTRY(ia32_sysenter_target)
 287         CFI_STARTPROC simple
 288         CFI_SIGNAL_FRAME
 289         CFI_DEF_CFA esp, 0
 290         CFI_REGISTER esp, ebp
 291         movl TSS_sysenter_sp0(%esp),%esp
 292 sysenter_past_esp:
 293         /*
 294          * Interrupts are disabled here, but we can't trace it until
 295          * enough kernel state to call TRACE_IRQS_OFF can be called - but
 296          * we immediately enable interrupts at that point anyway.
 297          */
 298         pushl $(__USER_DS)
 299         CFI_ADJUST_CFA_OFFSET 4
 300         /*CFI_REL_OFFSET ss, 0*/
 301         pushl %ebp
 302         CFI_ADJUST_CFA_OFFSET 4
 303         CFI_REL_OFFSET esp, 0
 304         pushfl
 305         orl $X86_EFLAGS_IF, (%esp)
 306         CFI_ADJUST_CFA_OFFSET 4
 307         pushl $(__USER_CS)
 308         CFI_ADJUST_CFA_OFFSET 4
 309         /*CFI_REL_OFFSET cs, 0*/
 310         /*
 311          * Push current_thread_info()->sysenter_return to the stack.
 312          * A tiny bit of offset fixup is necessary - 4*4 means the 4 words
 313          * pushed above; +8 corresponds to copy_thread's esp0 setting.
 314          */
 315         pushl (TI_sysenter_return-THREAD_SIZE+8+4*4)(%esp)
 316         CFI_ADJUST_CFA_OFFSET 4
 317         CFI_REL_OFFSET eip, 0
 318
 319         pushl %eax
 320         CFI_ADJUST_CFA_OFFSET 4
 321         SAVE_ALL
 322         ENABLE_INTERRUPTS(CLBR_NONE)
 323
 324 /*
 325  * Load the potential sixth argument from user stack.
 326  * Careful about security.
 327  */
 328         cmpl $__PAGE_OFFSET-3,%ebp
 329         jae syscall_fault
 330 1:      movl (%ebp),%ebp
 331         movl %ebp,PT_EBP(%esp)
 332 .section __ex_table,"a"
 333         .align 4
 334         .long 1b,syscall_fault
 335 .previous
 336
 337         GET_THREAD_INFO(%ebp)
 338
 339         /* Note, _TIF_SECCOMP is bit number 8, and so it needs testw and not testb */
 340         testw $(_TIF_SYSCALL_EMU|_TIF_SYSCALL_TRACE|_TIF_SECCOMP|_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
 341         jnz syscall_trace_entry
 342         cmpl $(nr_syscalls), %eax
 343         jae syscall_badsys
 344         call *sys_call_table(,%eax,4)
 345         movl %eax,PT_EAX(%esp)
 346         LOCKDEP_SYS_EXIT
 347         DISABLE_INTERRUPTS(CLBR_ANY)
 348         TRACE_IRQS_OFF
 349         movl TI_flags(%ebp), %ecx
 350         testw $_TIF_ALLWORK_MASK, %cx
 351         jne syscall_exit_work
 352 /* if something modifies registers it must also disable sysexit */
 353         movl PT_EIP(%esp), %edx
 354         movl PT_OLDESP(%esp), %ecx
 355         xorl %ebp,%ebp
 356         TRACE_IRQS_ON
 357 1:      mov  PT_FS(%esp), %fs
 358         ENABLE_INTERRUPTS_SYSCALL_RET
 359         CFI_ENDPROC
 360 .pushsection .fixup,"ax"
 361 2:      movl $0,PT_FS(%esp)
 362         jmp 1b
 363 .section __ex_table,"a"
 364         .align 4
 365         .long 1b,2b
 366 .popsection
 367 ENDPROC(ia32_sysenter_target)
 368
 369         # system call handler stub
 370 ENTRY(system_call)
 371         RING0_INT_FRAME                 # can't unwind into user space anyway
 372         pushl %eax                      # save orig_eax
 373         CFI_ADJUST_CFA_OFFSET 4
 374         SAVE_ALL
 375         GET_THREAD_INFO(%ebp)
 376                                         # system call tracing in operation / emulation
 377         /* Note, _TIF_SECCOMP is bit number 8, and so it needs testw and not testb */
 378         testw $(_TIF_SYSCALL_EMU|_TIF_SYSCALL_TRACE|_TIF_SECCOMP|_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
 379         jnz syscall_trace_entry
 380         cmpl $(nr_syscalls), %eax
 381         jae syscall_badsys
 382 syscall_call:
 383         call *sys_call_table(,%eax,4)
 384         movl %eax,PT_EAX(%esp)          # store the return value
 385 syscall_exit:
 386         LOCKDEP_SYS_EXIT
 387         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 388                                         # setting need_resched or sigpending
 389                                         # between sampling and the iret
 390         TRACE_IRQS_OFF
 391         testl $TF_MASK,PT_EFLAGS(%esp)  # If tracing set singlestep flag on exit
 392         jz no_singlestep
 393         orl $_TIF_SINGLESTEP,TI_flags(%ebp)
 394 no_singlestep:
 395         movl TI_flags(%ebp), %ecx
 396         testw $_TIF_ALLWORK_MASK, %cx   # current->work
 397         jne syscall_exit_work
 398
 399 restore_all:
 400         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS, SS and CS
 401         # Warning: PT_OLDSS(%esp) contains the wrong/random values if we
 402         # are returning to the kernel.
 403         # See comments in process.c:copy_thread() for details.
 404         movb PT_OLDSS(%esp), %ah
 405         movb PT_CS(%esp), %al
 406         andl $(VM_MASK | (SEGMENT_TI_MASK << 8) | SEGMENT_RPL_MASK), %eax
 407         cmpl $((SEGMENT_LDT << 8) | USER_RPL), %eax
 408         CFI_REMEMBER_STATE
 409         je ldt_ss                       # returning to user-space with LDT SS
 410 restore_nocheck:
 411         TRACE_IRQS_IRET
 412 restore_nocheck_notrace:
 413         RESTORE_REGS
 414         addl $4, %esp                   # skip orig_eax/error_code
 415         CFI_ADJUST_CFA_OFFSET -4
 416 irq_return:
 417         INTERRUPT_RETURN
 418 .section .fixup,"ax"
 419 iret_exc:
 420         pushl $0                        # no error code
 421         pushl $do_iret_error
 422         jmp error_code
 423 .previous
 424 .section __ex_table,"a"
 425         .align 4
 426         .long irq_return,iret_exc
 427 .previous
 428
 429         CFI_RESTORE_STATE
 430 ldt_ss:
 431         larl PT_OLDSS(%esp), %eax
 432         jnz restore_nocheck
 433         testl $0x00400000, %eax         # returning to 32bit stack?
 434         jnz restore_nocheck             # allright, normal return
 435
 436 #ifdef CONFIG_PARAVIRT
 437         /*
 438          * The kernel can't run on a non-flat stack if paravirt mode
 439          * is active.  Rather than try to fixup the high bits of
 440          * ESP, bypass this code entirely.  This may break DOSemu
 441          * and/or Wine support in a paravirt VM, although the option
 442          * is still available to implement the setting of the high
 443          * 16-bits in the INTERRUPT_RETURN paravirt-op.
 444          */
 445         cmpl $0, pv_info+PARAVIRT_enabled
 446         jne restore_nocheck
 447 #endif
 448
 449         /* If returning to userspace with 16bit stack,
 450          * try to fix the higher word of ESP, as the CPU
 451          * won't restore it.
 452          * This is an "official" bug of all the x86-compatible
 453          * CPUs, which we can try to work around to make
 454          * dosemu and wine happy. */
 455         movl PT_OLDESP(%esp), %eax
 456         movl %esp, %edx
 457         call patch_espfix_desc
 458         pushl $__ESPFIX_SS
 459         CFI_ADJUST_CFA_OFFSET 4
 460         pushl %eax
 461         CFI_ADJUST_CFA_OFFSET 4
 462         DISABLE_INTERRUPTS(CLBR_EAX)
 463         TRACE_IRQS_OFF
 464         lss (%esp), %esp
 465         CFI_ADJUST_CFA_OFFSET -8
 466         jmp restore_nocheck
 467         CFI_ENDPROC
 468 ENDPROC(system_call)
 469
 470         # perform work that needs to be done immediately before resumption
 471         ALIGN
 472         RING0_PTREGS_FRAME              # can't unwind into user space anyway
 473 work_pending:
 474         testb $_TIF_NEED_RESCHED, %cl
 475         jz work_notifysig
 476 work_resched:
 477         call schedule
 478         LOCKDEP_SYS_EXIT
 479         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 480                                         # setting need_resched or sigpending
 481                                         # between sampling and the iret
 482         TRACE_IRQS_OFF
 483         movl TI_flags(%ebp), %ecx
 484         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done other
 485                                         # than syscall tracing?
 486         jz restore_all
 487         testb $_TIF_NEED_RESCHED, %cl
 488         jnz work_resched
 489
 490 work_notifysig:                         # deal with pending signals and
 491                                         # notify-resume requests
 492 #ifdef CONFIG_VM86
 493         testl $VM_MASK, PT_EFLAGS(%esp)
 494         movl %esp, %eax
 495         jne work_notifysig_v86          # returning to kernel-space or
 496                                         # vm86-space
 497         xorl %edx, %edx
 498         call do_notify_resume
 499         jmp resume_userspace_sig
 500
 501         ALIGN
 502 work_notifysig_v86:
 503         pushl %ecx                      # save ti_flags for do_notify_resume
 504         CFI_ADJUST_CFA_OFFSET 4
 505         call save_v86_state             # %eax contains pt_regs pointer
 506         popl %ecx
 507         CFI_ADJUST_CFA_OFFSET -4
 508         movl %eax, %esp
 509 #else
 510         movl %esp, %eax
 511 #endif
 512         xorl %edx, %edx
 513         call do_notify_resume
 514         jmp resume_userspace_sig
 515 END(work_pending)
 516
 517         # perform syscall exit tracing
 518         ALIGN
 519 syscall_trace_entry:
 520         movl $-ENOSYS,PT_EAX(%esp)
 521         movl %esp, %eax
 522         xorl %edx,%edx
 523         call do_syscall_trace
 524         cmpl $0, %eax
 525         jne resume_userspace            # ret != 0 -> running under PTRACE_SYSEMU,
 526                                         # so must skip actual syscall
 527         movl PT_ORIG_EAX(%esp), %eax
 528         cmpl $(nr_syscalls), %eax
 529         jnae syscall_call
 530         jmp syscall_exit
 531 END(syscall_trace_entry)
 532
 533         # perform syscall exit tracing
 534         ALIGN
 535 syscall_exit_work:
 536         testb $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SINGLESTEP), %cl
 537         jz work_pending
 538         TRACE_IRQS_ON
 539         ENABLE_INTERRUPTS(CLBR_ANY)     # could let do_syscall_trace() call
 540                                         # schedule() instead
 541         movl %esp, %eax
 542         movl $1, %edx
 543         call do_syscall_trace
 544         jmp resume_userspace
 545 END(syscall_exit_work)
 546         CFI_ENDPROC
 547
 548         RING0_INT_FRAME                 # can't unwind into user space anyway
 549 syscall_fault:
 550         GET_THREAD_INFO(%ebp)
 551         movl $-EFAULT,PT_EAX(%esp)
 552         jmp resume_userspace
 553 END(syscall_fault)
 554
 555 syscall_badsys:
 556         movl $-ENOSYS,PT_EAX(%esp)
 557         jmp resume_userspace
 558 END(syscall_badsys)
 559         CFI_ENDPROC
 560
 561 #define FIXUP_ESPFIX_STACK \
 562         /* since we are on a wrong stack, we cant make it a C code :( */ \
 563         PER_CPU(gdt_page, %ebx); \
 564         GET_DESC_BASE(GDT_ENTRY_ESPFIX_SS, %ebx, %eax, %ax, %al, %ah); \
 565         addl %esp, %eax; \
 566         pushl $__KERNEL_DS; \
 567         CFI_ADJUST_CFA_OFFSET 4; \
 568         pushl %eax; \
 569         CFI_ADJUST_CFA_OFFSET 4; \
 570         lss (%esp), %esp; \
 571         CFI_ADJUST_CFA_OFFSET -8;
 572 #define UNWIND_ESPFIX_STACK \
 573         movl %ss, %eax; \
 574         /* see if on espfix stack */ \
 575         cmpw $__ESPFIX_SS, %ax; \
 576         jne 27f; \
 577         movl $__KERNEL_DS, %eax; \
 578         movl %eax, %ds; \
 579         movl %eax, %es; \
 580         /* switch to normal stack */ \
 581         FIXUP_ESPFIX_STACK; \
 582 27:;
 583
 584 /*
 585  * Build the entry stubs and pointer table with
 586  * some assembler magic.
 587  */
 588 .section .rodata,"a"
 589 ENTRY(interrupt)
 590 .text
 591
 592 ENTRY(irq_entries_start)
 593         RING0_INT_FRAME
 594 vector=0
 595 .rept NR_IRQS
 596         ALIGN
 597  .if vector
 598         CFI_ADJUST_CFA_OFFSET -4
 599  .endif
 600 1:      pushl $~(vector)
 601         CFI_ADJUST_CFA_OFFSET 4
 602         jmp common_interrupt
 603  .previous
 604         .long 1b
 605  .text
 606 vector=vector+1
 607 .endr
 608 END(irq_entries_start)
 609
 610 .previous
 611 END(interrupt)
 612 .previous
 613
 614 /*
 615  * the CPU automatically disables interrupts when executing an IRQ vector,
 616  * so IRQ-flags tracing has to follow that:
 617  */
 618         ALIGN
 619 common_interrupt:
 620         SAVE_ALL
 621         TRACE_IRQS_OFF
 622         movl %esp,%eax
 623         call do_IRQ
 624         jmp ret_from_intr
 625 ENDPROC(common_interrupt)
 626         CFI_ENDPROC
 627
 628 #define BUILD_INTERRUPT(name, nr)       \
 629 ENTRY(name)                             \
 630         RING0_INT_FRAME;                \
 631         pushl $~(nr);                   \
 632         CFI_ADJUST_CFA_OFFSET 4;        \
 633         SAVE_ALL;                       \
 634         TRACE_IRQS_OFF                  \
 635         movl %esp,%eax;                 \
 636         call smp_##name;                \
 637         jmp ret_from_intr;              \
 638         CFI_ENDPROC;                    \
 639 ENDPROC(name)
 640
 641 /* The include is where all of the SMP etc. interrupts come from */
 642 #include "entry_arch.h"
 643
 644 KPROBE_ENTRY(page_fault)
 645         RING0_EC_FRAME
 646         pushl $do_page_fault
 647         CFI_ADJUST_CFA_OFFSET 4
 648         ALIGN
 649 error_code:
 650         /* the function address is in %fs's slot on the stack */
 651         pushl %es
 652         CFI_ADJUST_CFA_OFFSET 4
 653         /*CFI_REL_OFFSET es, 0*/
 654         pushl %ds
 655         CFI_ADJUST_CFA_OFFSET 4
 656         /*CFI_REL_OFFSET ds, 0*/
 657         pushl %eax
 658         CFI_ADJUST_CFA_OFFSET 4
 659         CFI_REL_OFFSET eax, 0
 660         pushl %ebp
 661         CFI_ADJUST_CFA_OFFSET 4
 662         CFI_REL_OFFSET ebp, 0
 663         pushl %edi
 664         CFI_ADJUST_CFA_OFFSET 4
 665         CFI_REL_OFFSET edi, 0
 666         pushl %esi
 667         CFI_ADJUST_CFA_OFFSET 4
 668         CFI_REL_OFFSET esi, 0
 669         pushl %edx
 670         CFI_ADJUST_CFA_OFFSET 4
 671         CFI_REL_OFFSET edx, 0
 672         pushl %ecx
 673         CFI_ADJUST_CFA_OFFSET 4
 674         CFI_REL_OFFSET ecx, 0
 675         pushl %ebx
 676         CFI_ADJUST_CFA_OFFSET 4
 677         CFI_REL_OFFSET ebx, 0
 678         cld
 679         pushl %fs
 680         CFI_ADJUST_CFA_OFFSET 4
 681         /*CFI_REL_OFFSET fs, 0*/
 682         movl $(__KERNEL_PERCPU), %ecx
 683         movl %ecx, %fs
 684         UNWIND_ESPFIX_STACK
 685         popl %ecx
 686         CFI_ADJUST_CFA_OFFSET -4
 687         /*CFI_REGISTER es, ecx*/
 688         movl PT_FS(%esp), %edi          # get the function address
 689         movl PT_ORIG_EAX(%esp), %edx    # get the error code
 690         movl $-1, PT_ORIG_EAX(%esp)     # no syscall to restart
 691         mov  %ecx, PT_FS(%esp)
 692         /*CFI_REL_OFFSET fs, ES*/
 693         movl $(__USER_DS), %ecx
 694         movl %ecx, %ds
 695         movl %ecx, %es
 696         movl %esp,%eax                  # pt_regs pointer
 697         call *%edi
 698         jmp ret_from_exception
 699         CFI_ENDPROC
 700 KPROBE_END(page_fault)
 701
 702 ENTRY(coprocessor_error)
 703         RING0_INT_FRAME
 704         pushl $0
 705         CFI_ADJUST_CFA_OFFSET 4
 706         pushl $do_coprocessor_error
 707         CFI_ADJUST_CFA_OFFSET 4
 708         jmp error_code
 709         CFI_ENDPROC
 710 END(coprocessor_error)
 711
 712 ENTRY(simd_coprocessor_error)
 713         RING0_INT_FRAME
 714         pushl $0
 715         CFI_ADJUST_CFA_OFFSET 4
 716         pushl $do_simd_coprocessor_error
 717         CFI_ADJUST_CFA_OFFSET 4
 718         jmp error_code
 719         CFI_ENDPROC
 720 END(simd_coprocessor_error)
 721
 722 ENTRY(device_not_available)
 723         RING0_INT_FRAME
 724         pushl $-1                       # mark this as an int
 725         CFI_ADJUST_CFA_OFFSET 4
 726         SAVE_ALL
 727         GET_CR0_INTO_EAX
 728         testl $0x4, %eax                # EM (math emulation bit)
 729         jne device_not_available_emulate
 730         preempt_stop(CLBR_ANY)
 731         call math_state_restore
 732         jmp ret_from_exception
 733 device_not_available_emulate:
 734         pushl $0                        # temporary storage for ORIG_EIP
 735         CFI_ADJUST_CFA_OFFSET 4
 736         call math_emulate
 737         addl $4, %esp
 738         CFI_ADJUST_CFA_OFFSET -4
 739         jmp ret_from_exception
 740         CFI_ENDPROC
 741 END(device_not_available)
 742
 743 /*
 744  * Debug traps and NMI can happen at the one SYSENTER instruction
 745  * that sets up the real kernel stack. Check here, since we can't
 746  * allow the wrong stack to be used.
 747  *
 748  * "TSS_sysenter_sp0+12" is because the NMI/debug handler will have
 749  * already pushed 3 words if it hits on the sysenter instruction:
 750  * eflags, cs and eip.
 751  *
 752  * We just load the right stack, and push the three (known) values
 753  * by hand onto the new stack - while updating the return eip past
 754  * the instruction that would have done it for sysenter.
 755  */
 756 #define FIX_STACK(offset, ok, label)            \
 757         cmpw $__KERNEL_CS,4(%esp);              \
 758         jne ok;                                 \
 759 label:                                          \
 760         movl TSS_sysenter_sp0+offset(%esp),%esp;        \
 761         CFI_DEF_CFA esp, 0;                     \
 762         CFI_UNDEFINED eip;                      \
 763         pushfl;                                 \
 764         CFI_ADJUST_CFA_OFFSET 4;                \
 765         pushl $__KERNEL_CS;                     \
 766         CFI_ADJUST_CFA_OFFSET 4;                \
 767         pushl $sysenter_past_esp;               \
 768         CFI_ADJUST_CFA_OFFSET 4;                \
 769         CFI_REL_OFFSET eip, 0
 770
 771 KPROBE_ENTRY(debug)
 772         RING0_INT_FRAME
 773         cmpl $ia32_sysenter_target,(%esp)
 774         jne debug_stack_correct
 775         FIX_STACK(12, debug_stack_correct, debug_esp_fix_insn)
 776 debug_stack_correct:
 777         pushl $-1                       # mark this as an int
 778         CFI_ADJUST_CFA_OFFSET 4
 779         SAVE_ALL
 780         xorl %edx,%edx                  # error code 0
 781         movl %esp,%eax                  # pt_regs pointer
 782         call do_debug
 783         jmp ret_from_exception
 784         CFI_ENDPROC
 785 KPROBE_END(debug)
 786
 787 /*
 788  * NMI is doubly nasty. It can happen _while_ we're handling
 789  * a debug fault, and the debug fault hasn't yet been able to
 790  * clear up the stack. So we first check whether we got  an
 791  * NMI on the sysenter entry path, but after that we need to
 792  * check whether we got an NMI on the debug path where the debug
 793  * fault happened on the sysenter path.
 794  */
 795 KPROBE_ENTRY(nmi)
 796         RING0_INT_FRAME
 797         pushl %eax
 798         CFI_ADJUST_CFA_OFFSET 4
 799         movl %ss, %eax
 800         cmpw $__ESPFIX_SS, %ax
 801         popl %eax
 802         CFI_ADJUST_CFA_OFFSET -4
 803         je nmi_espfix_stack
 804         cmpl $ia32_sysenter_target,(%esp)
 805         je nmi_stack_fixup
 806         pushl %eax
 807         CFI_ADJUST_CFA_OFFSET 4
 808         movl %esp,%eax
 809         /* Do not access memory above the end of our stack page,
 810          * it might not exist.
 811          */
 812         andl $(THREAD_SIZE-1),%eax
 813         cmpl $(THREAD_SIZE-20),%eax
 814         popl %eax
 815         CFI_ADJUST_CFA_OFFSET -4
 816         jae nmi_stack_correct
 817         cmpl $ia32_sysenter_target,12(%esp)
 818         je nmi_debug_stack_check
 819 nmi_stack_correct:
 820         /* We have a RING0_INT_FRAME here */
 821         pushl %eax
 822         CFI_ADJUST_CFA_OFFSET 4
 823         SAVE_ALL
 824         xorl %edx,%edx          # zero error code
 825         movl %esp,%eax          # pt_regs pointer
 826         call do_nmi
 827         jmp restore_nocheck_notrace
 828         CFI_ENDPROC
 829
 830 nmi_stack_fixup:
 831         RING0_INT_FRAME
 832         FIX_STACK(12,nmi_stack_correct, 1)
 833         jmp nmi_stack_correct
 834
 835 nmi_debug_stack_check:
 836         /* We have a RING0_INT_FRAME here */
 837         cmpw $__KERNEL_CS,16(%esp)
 838         jne nmi_stack_correct
 839         cmpl $debug,(%esp)
 840         jb nmi_stack_correct
 841         cmpl $debug_esp_fix_insn,(%esp)
 842         ja nmi_stack_correct
 843         FIX_STACK(24,nmi_stack_correct, 1)
 844         jmp nmi_stack_correct
 845
 846 nmi_espfix_stack:
 847         /* We have a RING0_INT_FRAME here.
 848          *
 849          * create the pointer to lss back
 850          */
 851         pushl %ss
 852         CFI_ADJUST_CFA_OFFSET 4
 853         pushl %esp
 854         CFI_ADJUST_CFA_OFFSET 4
 855         addw $4, (%esp)
 856         /* copy the iret frame of 12 bytes */
 857         .rept 3
 858         pushl 16(%esp)
 859         CFI_ADJUST_CFA_OFFSET 4
 860         .endr
 861         pushl %eax
 862         CFI_ADJUST_CFA_OFFSET 4
 863         SAVE_ALL
 864         FIXUP_ESPFIX_STACK              # %eax == %esp
 865         xorl %edx,%edx                  # zero error code
 866         call do_nmi
 867         RESTORE_REGS
 868         lss 12+4(%esp), %esp            # back to espfix stack
 869         CFI_ADJUST_CFA_OFFSET -24
 870         jmp irq_return
 871         CFI_ENDPROC
 872 KPROBE_END(nmi)
 873
 874 #ifdef CONFIG_PARAVIRT
 875 ENTRY(native_iret)
 876         iret
 877 .section __ex_table,"a"
 878         .align 4
 879         .long native_iret, iret_exc
 880 .previous
 881 END(native_iret)
 882
 883 ENTRY(native_irq_enable_syscall_ret)
 884         sti
 885         sysexit
 886 END(native_irq_enable_syscall_ret)
 887 #endif
 888
 889 KPROBE_ENTRY(int3)
 890         RING0_INT_FRAME
 891         pushl $-1                       # mark this as an int
 892         CFI_ADJUST_CFA_OFFSET 4
 893         SAVE_ALL
 894         xorl %edx,%edx          # zero error code
 895         movl %esp,%eax          # pt_regs pointer
 896         call do_int3
 897         jmp ret_from_exception
 898         CFI_ENDPROC
 899 KPROBE_END(int3)
 900
 901 ENTRY(overflow)
 902         RING0_INT_FRAME
 903         pushl $0
 904         CFI_ADJUST_CFA_OFFSET 4
 905         pushl $do_overflow
 906         CFI_ADJUST_CFA_OFFSET 4
 907         jmp error_code
 908         CFI_ENDPROC
 909 END(overflow)
 910
 911 ENTRY(bounds)
 912         RING0_INT_FRAME
 913         pushl $0
 914         CFI_ADJUST_CFA_OFFSET 4
 915         pushl $do_bounds
 916         CFI_ADJUST_CFA_OFFSET 4
 917         jmp error_code
 918         CFI_ENDPROC
 919 END(bounds)
 920
 921 ENTRY(invalid_op)
 922         RING0_INT_FRAME
 923         pushl $0
 924         CFI_ADJUST_CFA_OFFSET 4
 925         pushl $do_invalid_op
 926         CFI_ADJUST_CFA_OFFSET 4
 927         jmp error_code
 928         CFI_ENDPROC
 929 END(invalid_op)
 930
 931 ENTRY(coprocessor_segment_overrun)
 932         RING0_INT_FRAME
 933         pushl $0
 934         CFI_ADJUST_CFA_OFFSET 4
 935         pushl $do_coprocessor_segment_overrun
 936         CFI_ADJUST_CFA_OFFSET 4
 937         jmp error_code
 938         CFI_ENDPROC
 939 END(coprocessor_segment_overrun)
 940
 941 ENTRY(invalid_TSS)
 942         RING0_EC_FRAME
 943         pushl $do_invalid_TSS
 944         CFI_ADJUST_CFA_OFFSET 4
 945         jmp error_code
 946         CFI_ENDPROC
 947 END(invalid_TSS)
 948
 949 ENTRY(segment_not_present)
 950         RING0_EC_FRAME
 951         pushl $do_segment_not_present
 952         CFI_ADJUST_CFA_OFFSET 4
 953         jmp error_code
 954         CFI_ENDPROC
 955 END(segment_not_present)
 956
 957 ENTRY(stack_segment)
 958         RING0_EC_FRAME
 959         pushl $do_stack_segment
 960         CFI_ADJUST_CFA_OFFSET 4
 961         jmp error_code
 962         CFI_ENDPROC
 963 END(stack_segment)
 964
 965 KPROBE_ENTRY(general_protection)
 966         RING0_EC_FRAME
 967         pushl $do_general_protection
 968         CFI_ADJUST_CFA_OFFSET 4
 969         jmp error_code
 970         CFI_ENDPROC
 971 KPROBE_END(general_protection)
 972
 973 ENTRY(alignment_check)
 974         RING0_EC_FRAME
 975         pushl $do_alignment_check
 976         CFI_ADJUST_CFA_OFFSET 4
 977         jmp error_code
 978         CFI_ENDPROC
 979 END(alignment_check)
 980
 981 ENTRY(divide_error)
 982         RING0_INT_FRAME
 983         pushl $0                        # no error code
 984         CFI_ADJUST_CFA_OFFSET 4
 985         pushl $do_divide_error
 986         CFI_ADJUST_CFA_OFFSET 4
 987         jmp error_code
 988         CFI_ENDPROC
 989 END(divide_error)
 990
 991 #ifdef CONFIG_X86_MCE
 992 ENTRY(machine_check)
 993         RING0_INT_FRAME
 994         pushl $0
 995         CFI_ADJUST_CFA_OFFSET 4
 996         pushl machine_check_vector
 997         CFI_ADJUST_CFA_OFFSET 4
 998         jmp error_code
 999         CFI_ENDPROC
1000 END(machine_check)
1001 #endif
1002
1003 ENTRY(spurious_interrupt_bug)
1004         RING0_INT_FRAME
1005         pushl $0
1006         CFI_ADJUST_CFA_OFFSET 4
1007         pushl $do_spurious_interrupt_bug
1008         CFI_ADJUST_CFA_OFFSET 4
1009         jmp error_code
1010         CFI_ENDPROC
1011 END(spurious_interrupt_bug)
1012
1013 ENTRY(kernel_thread_helper)
1014         pushl $0                # fake return address for unwinder
1015         CFI_STARTPROC
1016         movl %edx,%eax
1017         push %edx
1018         CFI_ADJUST_CFA_OFFSET 4
1019         call *%ebx
1020         push %eax
1021         CFI_ADJUST_CFA_OFFSET 4
1022         call do_exit
1023         CFI_ENDPROC
1024 ENDPROC(kernel_thread_helper)
1025
1026 #ifdef CONFIG_XEN
1027 ENTRY(xen_hypervisor_callback)
1028         CFI_STARTPROC
1029         pushl $0
1030         CFI_ADJUST_CFA_OFFSET 4
1031         SAVE_ALL
1032         TRACE_IRQS_OFF
1033
1034         /* Check to see if we got the event in the critical
1035            region in xen_iret_direct, after we've reenabled
1036            events and checked for pending events.  This simulates
1037            iret instruction's behaviour where it delivers a
1038            pending interrupt when enabling interrupts. */
1039         movl PT_EIP(%esp),%eax
1040         cmpl $xen_iret_start_crit,%eax
1041         jb   1f
1042         cmpl $xen_iret_end_crit,%eax
1043         jae  1f
1044
1045         call xen_iret_crit_fixup
1046
1047 1:      mov %esp, %eax
1048         call xen_evtchn_do_upcall
1049         jmp  ret_from_intr
1050         CFI_ENDPROC
1051 ENDPROC(xen_hypervisor_callback)
1052
1053 # Hypervisor uses this for application faults while it executes.
1054 # We get here for two reasons:
1055 #  1. Fault while reloading DS, ES, FS or GS
1056 #  2. Fault while executing IRET
1057 # Category 1 we fix up by reattempting the load, and zeroing the segment
1058 # register if the load fails.
1059 # Category 2 we fix up by jumping to do_iret_error. We cannot use the
1060 # normal Linux return path in this case because if we use the IRET hypercall
1061 # to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1062 # We distinguish between categories by maintaining a status value in EAX.
1063 ENTRY(xen_failsafe_callback)
1064         CFI_STARTPROC
1065         pushl %eax
1066         CFI_ADJUST_CFA_OFFSET 4
1067         movl $1,%eax
1068 1:      mov 4(%esp),%ds
1069 2:      mov 8(%esp),%es
1070 3:      mov 12(%esp),%fs
1071 4:      mov 16(%esp),%gs
1072         testl %eax,%eax
1073         popl %eax
1074         CFI_ADJUST_CFA_OFFSET -4
1075         lea 16(%esp),%esp
1076         CFI_ADJUST_CFA_OFFSET -16
1077         jz 5f
1078         addl $16,%esp
1079         jmp iret_exc            # EAX != 0 => Category 2 (Bad IRET)
1080 5:      pushl $0                # EAX == 0 => Category 1 (Bad segment)
1081         CFI_ADJUST_CFA_OFFSET 4
1082         SAVE_ALL
1083         jmp ret_from_exception
1084         CFI_ENDPROC
1085
1086 .section .fixup,"ax"
1087 6:      xorl %eax,%eax
1088         movl %eax,4(%esp)
1089         jmp 1b
1090 7:      xorl %eax,%eax
1091         movl %eax,8(%esp)
1092         jmp 2b
1093 8:      xorl %eax,%eax
1094         movl %eax,12(%esp)
1095         jmp 3b
1096 9:      xorl %eax,%eax
1097         movl %eax,16(%esp)
1098         jmp 4b
1099 .previous
1100 .section __ex_table,"a"
1101         .align 4
1102         .long 1b,6b
1103         .long 2b,7b
1104         .long 3b,8b
1105         .long 4b,9b
1106 .previous
1107 ENDPROC(xen_failsafe_callback)
1108
1109 #endif  /* CONFIG_XEN */
1110
1111 .section .rodata,"a"
1112 #include "syscall_table_32.S"
1113
1114 syscall_table_size=(.-sys_call_table)