err.no Git - linux-2.6/blob - arch/sh/kernel/vmlinux.lds.S

   1 /* $Id: vmlinux.lds.S,v 1.8 2003/05/16 17:18:14 lethal Exp $
   2  * ld script to make SuperH Linux kernel
   3  * Written by Niibe Yutaka
   4  */
   5 #include <asm/thread_info.h>
   6 #include <asm/cache.h>
   7 #include <asm-generic/vmlinux.lds.h>
   8
   9 #ifdef CONFIG_CPU_LITTLE_ENDIAN
  10 OUTPUT_FORMAT("elf32-sh-linux", "elf32-sh-linux", "elf32-sh-linux")
  11 #else
  12 OUTPUT_FORMAT("elf32-shbig-linux", "elf32-shbig-linux", "elf32-shbig-linux")
  13 #endif
  14 OUTPUT_ARCH(sh)
  15 ENTRY(_start)
  16 SECTIONS
  17 {
  18   . = CONFIG_PAGE_OFFSET + CONFIG_MEMORY_START + CONFIG_ZERO_PAGE_OFFSET;
  19   _text = .;                    /* Text and read-only data */
  20   text = .;                     /* Text and read-only data */
  21   .empty_zero_page : {
  22         *(.empty_zero_page)
  23         } = 0
  24   .text : {
  25         *(.text.head)
  26         TEXT_TEXT
  27         SCHED_TEXT
  28         LOCK_TEXT
  29         *(.fixup)
  30         *(.gnu.warning)
  31         } = 0x0009
  32
  33   . = ALIGN(16);                /* Exception table */
  34   __start___ex_table = .;
  35   __ex_table : { *(__ex_table) }
  36   __stop___ex_table = .;
  37
  38   _etext = .;                   /* End of text section */
  39
  40   RODATA
  41
  42   BUG_TABLE
  43
  44   .data : {                     /* Data */
  45         DATA_DATA
  46
  47          /* Align the initial ramdisk image (INITRD) on page boundaries. */
  48          . = ALIGN(PAGE_SIZE);
  49          __rd_start = .;
  50          *(.initrd)
  51          . = ALIGN(PAGE_SIZE);
  52          __rd_end = .;
  53
  54         CONSTRUCTORS
  55         }
  56
  57   . = ALIGN(PAGE_SIZE);
  58   .data.page_aligned : { *(.data.page_aligned) }
  59   __nosave_begin = .;
  60   .data_nosave : { *(.data.nosave) }
  61   . = ALIGN(PAGE_SIZE);
  62   __nosave_end = .;
  63
  64   PERCPU(PAGE_SIZE)
  65
  66   . = ALIGN(L1_CACHE_BYTES);
  67   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
  68
  69   _edata = .;                   /* End of data section */
  70
  71   . = ALIGN(THREAD_SIZE);               /* init_task */
  72   .data.init_task : { *(.data.init_task) }
  73
  74   . = ALIGN(PAGE_SIZE);         /* Init code and data */
  75   __init_begin = .;
  76   _sinittext = .;
  77   .init.text : { *(.init.text) }
  78   _einittext = .;
  79   .init.data : { *(.init.data) }
  80   . = ALIGN(16);
  81   __setup_start = .;
  82   .init.setup : { *(.init.setup) }
  83   __setup_end = .;
  84   __initcall_start = .;
  85   .initcall.init : {
  86         INITCALLS
  87   }
  88   __initcall_end = .;
  89   __con_initcall_start = .;
  90   .con_initcall.init : { *(.con_initcall.init) }
  91   __con_initcall_end = .;
  92   SECURITY_INIT
  93
  94 #ifdef CONFIG_BLK_DEV_INITRD
  95   . = ALIGN(PAGE_SIZE);
  96
  97   __initramfs_start = .;
  98   .init.ramfs : { *(.init.ramfs) }
  99   __initramfs_end = .;
 100 #endif
 101
 102  . = ALIGN(4);
 103   __machvec_start = .;
 104   .machvec.init : { *(.machvec.init) }
 105   __machvec_end = .;
 106
 107   . = ALIGN(PAGE_SIZE);
 108   .bss : {
 109         __init_end = .;
 110         __bss_start = .;                /* BSS */
 111         *(.bss.page_aligned)
 112         *(.bss)
 113         . = ALIGN(4);
 114         _ebss = .;                      /* uClinux MTD sucks */
 115         _end = . ;
 116   }
 117
 118   /* When something in the kernel is NOT compiled as a module, the
 119    * module cleanup code and data are put into these segments.  Both
 120    * can then be thrown away, as cleanup code is never called unless
 121    * it's a module.
 122    */
 123   /DISCARD/ : {
 124         *(.exitcall.exit)
 125         }
 126
 127   STABS_DEBUG
 128
 129   DWARF_DEBUG
 130 }