err.no Git - linux-2.6/blob - arch/s390/kernel/head64.S

   1 /*
   2  * arch/s390/kernel/head64.S
   3  *
   4  * Copyright (C) IBM Corp. 1999,2006
   5  *
   6  *   Author(s): Hartmut Penner <hp@de.ibm.com>
   7  *              Martin Schwidefsky <schwidefsky@de.ibm.com>
   8  *              Rob van der Heij <rvdhei@iae.nl>
   9  *              Heiko Carstens <heiko.carstens@de.ibm.com>
  10  *
  11  */
  12
  13 #
  14 # startup-code at 0x10000, running in absolute addressing mode
  15 # this is called either by the ipl loader or directly by PSW restart
  16 # or linload or SALIPL
  17 #
  18         .org    0x10000
  19 startup:basr    %r13,0                  # get base
  20 .LPG0:  l       %r13,0f-.LPG0(%r13)
  21         b       0(%r13)
  22 0:      .long   startup_continue
  23
  24 #
  25 # params at 10400 (setup.h)
  26 #
  27         .org    PARMAREA
  28         .quad   0                       # IPL_DEVICE
  29         .quad   0                       # INITRD_START
  30         .quad   0                       # INITRD_SIZE
  31
  32         .org    COMMAND_LINE
  33         .byte   "root=/dev/ram0 ro"
  34         .byte   0
  35
  36         .org    0x11000
  37
  38 startup_continue:
  39         basr    %r13,0                  # get base
  40 .LPG1:  sll     %r13,1                  # remove high order bit
  41         srl     %r13,1
  42         lhi     %r1,1                   # mode 1 = esame
  43         mvi     __LC_AR_MODE_ID,1       # set esame flag
  44         slr     %r0,%r0                 # set cpuid to zero
  45         sigp    %r1,%r0,0x12            # switch to esame mode
  46         sam64                           # switch to 64 bit mode
  47         lctlg   %c0,%c15,.Lctl-.LPG1(%r13)      # load control registers
  48         lg      %r12,.Lparmaddr-.LPG1(%r13)     # pointer to parameter area
  49                                         # move IPL device to lowcore
  50         mvc     __LC_IPLDEV(4),IPL_DEVICE+4-PARMAREA(%r12)
  51 #
  52 # Setup stack
  53 #
  54         larl    %r15,init_thread_union
  55         lg      %r14,__TI_task(%r15)    # cache current in lowcore
  56         stg     %r14,__LC_CURRENT
  57         aghi    %r15,1<<(PAGE_SHIFT+THREAD_ORDER) # init_task_union + THREAD_SIZE
  58         stg     %r15,__LC_KERNEL_STACK  # set end of kernel stack
  59         aghi    %r15,-160
  60         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15) # clear backchain
  61
  62         brasl   %r14,ipl_save_parameters
  63 #
  64 # clear bss memory
  65 #
  66         larl    %r2,__bss_start         # start of bss segment
  67         larl    %r3,_end                # end of bss segment
  68         sgr     %r3,%r2                 # length of bss
  69         sgr     %r4,%r4                 #
  70         sgr     %r5,%r5                 # set src,length and pad to zero
  71         mvcle   %r2,%r4,0               # clear mem
  72         jo      .-4                     # branch back, if not finish
  73                                         # set program check new psw mask
  74         mvc     __LC_PGM_NEW_PSW(8),.Lpcmsk-.LPG1(%r13)
  75         larl    %r1,.Lslowmemdetect     # set program check address
  76         stg     %r1,__LC_PGM_NEW_PSW+8
  77         lghi    %r1,0xc
  78         diag    %r0,%r1,0x260           # get memory size of virtual machine
  79         cgr     %r0,%r1                 # different? -> old detection routine
  80         jne     .Lslowmemdetect
  81         aghi    %r1,1                   # size is one more than end
  82         larl    %r2,memory_chunk
  83         stg     %r1,8(%r2)              # store size of chunk
  84         larl    %r2,memory_size
  85         stg     %r1,0(%r2)              # set memory size
  86         j       .Ldonemem
  87
  88 .Lslowmemdetect:
  89         l       %r2,.Lrcp-.LPG1(%r13)   # Read SCP forced command word
  90 .Lservicecall:
  91         stosm   .Lpmask-.LPG1(%r13),0x01        # authorize ext interrupts
  92
  93         stctg   %r0,%r0,.Lcr-.LPG1(%r13)        # get cr0
  94         la      %r1,0x200               # set bit 22
  95         og      %r1,.Lcr-.LPG1(%r13)    # or old cr0 with r1
  96         stg     %r1,.Lcr-.LPG1(%r13)
  97         lctlg   %r0,%r0,.Lcr-.LPG1(%r13)        # load modified cr0
  98
  99         mvc     __LC_EXT_NEW_PSW(8),.Lpcmsk-.LPG1(%r13) # set postcall psw
 100         larl    %r1,.Lsclph
 101         stg     %r1,__LC_EXT_NEW_PSW+8  # set handler
 102
 103         larl    %r4,.Lsccb              # %r4 is our index for sccb stuff
 104         lgr     %r1,%r4                 # our sccb
 105         .insn   rre,0xb2200000,%r2,%r1  # service call
 106         ipm     %r1
 107         srl     %r1,28                  # get cc code
 108         xr      %r3,%r3
 109         chi     %r1,3
 110         be      .Lfchunk-.LPG1(%r13)    # leave
 111         chi     %r1,2
 112         be      .Lservicecall-.LPG1(%r13)
 113         lpswe   .Lwaitsclp-.LPG1(%r13)
 114 .Lsclph:
 115         lh      %r1,.Lsccbr-.Lsccb(%r4)
 116         chi     %r1,0x10                # 0x0010 is the sucess code
 117         je      .Lprocsccb              # let's process the sccb
 118         chi     %r1,0x1f0
 119         bne     .Lfchunk-.LPG1(%r13)    # unhandled error code
 120         c       %r2,.Lrcp-.LPG1(%r13)   # Did we try Read SCP forced
 121         bne     .Lfchunk-.LPG1(%r13)    # if no, give up
 122         l       %r2,.Lrcp2-.LPG1(%r13)  # try with Read SCP
 123         b       .Lservicecall-.LPG1(%r13)
 124 .Lprocsccb:
 125         lghi    %r1,0
 126         icm     %r1,3,.Lscpincr1-.Lsccb(%r4)    # use this one if != 0
 127         jnz     .Lscnd
 128         lg      %r1,.Lscpincr2-.Lsccb(%r4)      # otherwise use this one
 129 .Lscnd:
 130         xr      %r3,%r3                 # same logic
 131         ic      %r3,.Lscpa1-.Lsccb(%r4)
 132         chi     %r3,0x00
 133         jne     .Lcompmem
 134         l       %r3,.Lscpa2-.Lsccb(%r4)
 135 .Lcompmem:
 136         mlgr    %r2,%r1                 # mem in MB on 128-bit
 137         l       %r1,.Lonemb-.LPG1(%r13)
 138         mlgr    %r2,%r1                 # mem size in bytes in %r3
 139         b       .Lfchunk-.LPG1(%r13)
 140
 141         .align  4
 142 .Lpmask:
 143         .byte   0
 144         .align  8
 145 .Lcr:
 146         .quad   0x00  # place holder for cr0
 147 .Lwaitsclp:
 148         .quad   0x0102000180000000,.Lsclph
 149 .Lrcp:
 150         .int    0x00120001 # Read SCP forced code
 151 .Lrcp2:
 152         .int    0x00020001 # Read SCP code
 153 .Lonemb:
 154         .int    0x100000
 155
 156 .Lfchunk:
 157
 158 #
 159 # find memory chunks.
 160 #
 161         lgr     %r9,%r3                 # end of mem
 162         larl    %r1,.Lchkmem            # set program check address
 163         stg     %r1,__LC_PGM_NEW_PSW+8
 164         la      %r1,1                   # test in increments of 128KB
 165         sllg    %r1,%r1,17
 166         larl    %r3,memory_chunk
 167         slgr    %r4,%r4                 # set start of chunk to zero
 168         slgr    %r5,%r5                 # set end of chunk to zero
 169         slr     %r6,%r6                 # set access code to zero
 170         la      %r10,MEMORY_CHUNKS      # number of chunks
 171 .Lloop:
 172         tprot   0(%r5),0                # test protection of first byte
 173         ipm     %r7
 174         srl     %r7,28
 175         clr     %r6,%r7                 # compare cc with last access code
 176         je      .Lsame
 177         j       .Lchkmem
 178 .Lsame:
 179         algr    %r5,%r1                 # add 128KB to end of chunk
 180                                         # no need to check here,
 181         brc     12,.Lloop               # this is the same chunk
 182 .Lchkmem:                               # > 16EB or tprot got a program check
 183         clgr    %r4,%r5                 # chunk size > 0?
 184         je      .Lchkloop
 185         stg     %r4,0(%r3)              # store start address of chunk
 186         lgr     %r0,%r5
 187         slgr    %r0,%r4
 188         stg     %r0,8(%r3)              # store size of chunk
 189         st      %r6,20(%r3)             # store type of chunk
 190         la      %r3,24(%r3)
 191         larl    %r8,memory_size
 192         stg     %r5,0(%r8)              # store memory size
 193         ahi     %r10,-1                 # update chunk number
 194 .Lchkloop:
 195         lr      %r6,%r7                 # set access code to last cc
 196         # we got an exception or we're starting a new
 197         # chunk , we must check if we should
 198         # still try to find valid memory (if we detected
 199         # the amount of available storage), and if we
 200         # have chunks left
 201         lghi    %r4,1
 202         sllg    %r4,%r4,31
 203         clgr    %r5,%r4
 204         je      .Lhsaskip
 205         xr      %r0, %r0
 206         clgr    %r0, %r9                # did we detect memory?
 207         je      .Ldonemem               # if not, leave
 208         chi     %r10, 0                 # do we have chunks left?
 209         je      .Ldonemem
 210 .Lhsaskip:
 211         algr    %r5,%r1                 # add 128KB to end of chunk
 212         lgr     %r4,%r5                 # potential new chunk
 213         clgr    %r5,%r9                 # should we go on?
 214         jl      .Lloop
 215 .Ldonemem:
 216
 217         larl    %r12,machine_flags
 218 #
 219 # find out if we are running under VM
 220 #
 221         stidp   __LC_CPUID              # store cpuid
 222         tm      __LC_CPUID,0xff         # running under VM ?
 223         bno     0f-.LPG1(%r13)
 224         oi      7(%r12),1               # set VM flag
 225 0:      lh      %r0,__LC_CPUID+4        # get cpu version
 226         chi     %r0,0x7490              # running on a P/390 ?
 227         bne     1f-.LPG1(%r13)
 228         oi      7(%r12),4               # set P/390 flag
 229 1:
 230
 231 #
 232 # find out if we have the MVPG instruction
 233 #
 234         la      %r1,0f-.LPG1(%r13)      # set program check address
 235         stg     %r1,__LC_PGM_NEW_PSW+8
 236         sgr     %r0,%r0
 237         lghi    %r1,0
 238         lghi    %r2,0
 239         mvpg    %r1,%r2                 # test MVPG instruction
 240         oi      7(%r12),16              # set MVPG flag
 241 0:
 242
 243 #
 244 # find out if the diag 0x44 works in 64 bit mode
 245 #
 246         la      %r1,0f-.LPG1(%r13)      # set program check address
 247         stg     %r1,__LC_PGM_NEW_PSW+8
 248         diag    0,0,0x44                # test diag 0x44
 249         oi      7(%r12),32              # set diag44 flag
 250 0:
 251
 252 #
 253 # find out if we have the IDTE instruction
 254 #
 255         la      %r1,0f-.LPG1(%r13)      # set program check address
 256         stg     %r1,__LC_PGM_NEW_PSW+8
 257         .long   0xb2b10000              # store facility list
 258         tm      0xc8,0x08               # check bit for clearing-by-ASCE
 259         bno     0f-.LPG1(%r13)
 260         lhi     %r1,2094
 261         lhi     %r2,0
 262         .long   0xb98e2001
 263         oi      7(%r12),0x80            # set IDTE flag
 264 0:
 265
 266 #
 267 # find out if the diag 0x9c is available
 268 #
 269         la      %r1,0f-.LPG1(%r13)      # set program check address
 270         stg     %r1,__LC_PGM_NEW_PSW+8
 271         stap    __LC_CPUID+4            # store cpu address
 272         lh      %r1,__LC_CPUID+4
 273         diag    %r1,0,0x9c              # test diag 0x9c
 274         oi      6(%r12),1               # set diag9c flag
 275 0:
 276
 277 #
 278 # find out if we have the MVCOS instruction
 279 #
 280         la      %r1,0f-.LPG1(%r13)      # set program check address
 281         stg     %r1,__LC_PGM_NEW_PSW+8
 282         .short  0xc800                  # mvcos 0(%r0),0(%r0),%r0
 283         .short  0x0000
 284         .short  0x0000
 285 0:      tm      0x8f,0x13               # special-operation exception?
 286         bno     1f-.LPG1(%r13)          # if yes, MVCOS is present
 287         oi      6(%r12),2               # set MVCOS flag
 288 1:
 289
 290         lpswe   .Lentry-.LPG1(13)       # jump to _stext in primary-space,
 291                                         # virtual and never return ...
 292         .align  16
 293 .Lentry:.quad   0x0000000180000000,_stext
 294 .Lctl:  .quad   0x04b50002              # cr0: various things
 295         .quad   0                       # cr1: primary space segment table
 296         .quad   .Lduct                  # cr2: dispatchable unit control table
 297         .quad   0                       # cr3: instruction authorization
 298         .quad   0                       # cr4: instruction authorization
 299         .quad   0xffffffffffffffff      # cr5: primary-aste origin
 300         .quad   0                       # cr6:  I/O interrupts
 301         .quad   0                       # cr7:  secondary space segment table
 302         .quad   0                       # cr8:  access registers translation
 303         .quad   0                       # cr9:  tracing off
 304         .quad   0                       # cr10: tracing off
 305         .quad   0                       # cr11: tracing off
 306         .quad   0                       # cr12: tracing off
 307         .quad   0                       # cr13: home space segment table
 308         .quad   0xc0000000              # cr14: machine check handling off
 309         .quad   0                       # cr15: linkage stack operations
 310 .Lduct: .long   0,0,0,0,0,0,0,0
 311         .long   0,0,0,0,0,0,0,0
 312 .Lpcmsk:.quad   0x0000000180000000
 313 .L4malign:.quad 0xffffffffffc00000
 314 .Lscan2g:.quad  0x80000000 + 0x20000 - 8        # 2GB + 128K - 8
 315 .Lnop:  .long   0x07000700
 316 .Lparmaddr:
 317         .quad   PARMAREA
 318
 319         .globl  ipl_schib
 320 ipl_schib:
 321         .rept 13
 322         .long 0
 323         .endr
 324
 325         .globl  ipl_flags
 326 ipl_flags:
 327         .long   0
 328         .globl  ipl_devno
 329 ipl_devno:
 330         .word 0
 331
 332         .org    0x12000
 333 .globl s390_readinfo_sccb
 334 s390_readinfo_sccb:
 335 .Lsccb:
 336         .hword  0x1000                  # length, one page
 337         .byte   0x00,0x00,0x00
 338         .byte   0x80                    # variable response bit set
 339 .Lsccbr:
 340         .hword  0x00                    # response code
 341 .Lscpincr1:
 342         .hword  0x00
 343 .Lscpa1:
 344         .byte   0x00
 345         .fill   89,1,0
 346 .Lscpa2:
 347         .int    0x00
 348 .Lscpincr2:
 349         .quad   0x00
 350         .fill   3984,1,0
 351         .org    0x13000
 352
 353 #ifdef CONFIG_SHARED_KERNEL
 354         .org    0x100000
 355 #endif
 356
 357 #
 358 # startup-code, running in absolute addressing mode
 359 #
 360         .globl  _stext
 361 _stext: basr    %r13,0                  # get base
 362 .LPG3:
 363 # check control registers
 364         stctg   %c0,%c15,0(%r15)
 365         oi      6(%r15),0x40            # enable sigp emergency signal
 366         oi      4(%r15),0x10            # switch on low address proctection
 367         lctlg   %c0,%c15,0(%r15)
 368
 369         lam     0,15,.Laregs-.LPG3(%r13)        # load acrs needed by uaccess
 370         brasl   %r14,start_kernel       # go to C code
 371 #
 372 # We returned from start_kernel ?!? PANIK
 373 #
 374         basr    %r13,0
 375         lpswe   .Ldw-.(%r13)            # load disabled wait psw
 376
 377         .align  8
 378 .Ldw:   .quad   0x0002000180000000,0x0000000000000000
 379 .Laregs:.long   0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0