err.no Git - linux-2.6/blob - arch/ia64/kernel/vmlinux.lds.S

   1
   2 #include <asm/cache.h>
   3 #include <asm/ptrace.h>
   4 #include <asm/system.h>
   5 #include <asm/pgtable.h>
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8
   9 #define IVT_TEXT                                                        \
  10                 VMLINUX_SYMBOL(__start_ivt_text) = .;                   \
  11                 *(.text.ivt)                                            \
  12                 VMLINUX_SYMBOL(__end_ivt_text) = .;
  13
  14 OUTPUT_FORMAT("elf64-ia64-little")
  15 OUTPUT_ARCH(ia64)
  16 ENTRY(phys_start)
  17 jiffies = jiffies_64;
  18 PHDRS {
  19   code   PT_LOAD;
  20   percpu PT_LOAD;
  21   data   PT_LOAD;
  22   note   PT_NOTE;
  23   unwind 0x70000001; /* PT_IA_64_UNWIND, but ld doesn't match the name */
  24 }
  25 SECTIONS
  26 {
  27   /* Sections to be discarded */
  28   /DISCARD/ : {
  29         EXIT_TEXT
  30         EXIT_DATA
  31         *(.exitcall.exit)
  32         *(.IA_64.unwind.exit.text)
  33         *(.IA_64.unwind_info.exit.text)
  34         }
  35
  36   v = PAGE_OFFSET;      /* this symbol is here to make debugging easier... */
  37   phys_start = _start - LOAD_OFFSET;
  38
  39   code : { } :code
  40   . = KERNEL_START;
  41
  42   _text = .;
  43   _stext = .;
  44
  45   .text : AT(ADDR(.text) - LOAD_OFFSET)
  46     {
  47         IVT_TEXT
  48         TEXT_TEXT
  49         SCHED_TEXT
  50         LOCK_TEXT
  51         KPROBES_TEXT
  52         *(.gnu.linkonce.t*)
  53     }
  54   .text.head : AT(ADDR(.text.head) - LOAD_OFFSET)
  55         { *(.text.head) }
  56   .text2 : AT(ADDR(.text2) - LOAD_OFFSET)
  57         { *(.text2) }
  58 #ifdef CONFIG_SMP
  59   .text.lock : AT(ADDR(.text.lock) - LOAD_OFFSET)
  60         { *(.text.lock) }
  61 #endif
  62   _etext = .;
  63
  64   /* Read-only data */
  65
  66   NOTES :code :note             /* put .notes in text and mark in PT_NOTE  */
  67   code_continues : {} :code     /* switch back to regular program...  */
  68
  69   /* Exception table */
  70   . = ALIGN(16);
  71   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET)
  72         {
  73           __start___ex_table = .;
  74           *(__ex_table)
  75           __stop___ex_table = .;
  76         }
  77
  78   /* MCA table */
  79   . = ALIGN(16);
  80   __mca_table : AT(ADDR(__mca_table) - LOAD_OFFSET)
  81         {
  82           __start___mca_table = .;
  83           *(__mca_table)
  84           __stop___mca_table = .;
  85         }
  86
  87   .data.patch.phys_stack_reg : AT(ADDR(.data.patch.phys_stack_reg) - LOAD_OFFSET)
  88         {
  89           __start___phys_stack_reg_patchlist = .;
  90           *(.data.patch.phys_stack_reg)
  91           __end___phys_stack_reg_patchlist = .;
  92         }
  93
  94   /* Global data */
  95   _data = .;
  96
  97   /* Unwind info & table: */
  98   . = ALIGN(8);
  99   .IA_64.unwind_info : AT(ADDR(.IA_64.unwind_info) - LOAD_OFFSET)
 100         { *(.IA_64.unwind_info*) }
 101   .IA_64.unwind : AT(ADDR(.IA_64.unwind) - LOAD_OFFSET)
 102         {
 103           __start_unwind = .;
 104           *(.IA_64.unwind*)
 105           __end_unwind = .;
 106         } :code :unwind
 107   code_continues2 : {} : code
 108
 109   RODATA
 110
 111   .opd : AT(ADDR(.opd) - LOAD_OFFSET)
 112         { *(.opd) }
 113
 114   /* Initialization code and data: */
 115
 116   . = ALIGN(PAGE_SIZE);
 117   __init_begin = .;
 118   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET)
 119         {
 120           _sinittext = .;
 121           INIT_TEXT
 122           _einittext = .;
 123         }
 124
 125   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET)
 126         { INIT_DATA }
 127
 128 #ifdef CONFIG_BLK_DEV_INITRD
 129   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET)
 130         {
 131           __initramfs_start = .;
 132           *(.init.ramfs)
 133           __initramfs_end = .;
 134         }
 135 #endif
 136
 137    . = ALIGN(16);
 138   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET)
 139         {
 140           __setup_start = .;
 141           *(.init.setup)
 142           __setup_end = .;
 143         }
 144   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET)
 145         {
 146           __initcall_start = .;
 147         INITCALLS
 148           __initcall_end = .;
 149         }
 150
 151   .data.patch.vtop : AT(ADDR(.data.patch.vtop) - LOAD_OFFSET)
 152         {
 153           __start___vtop_patchlist = .;
 154           *(.data.patch.vtop)
 155           __end___vtop_patchlist = .;
 156         }
 157
 158   .data.patch.rse : AT(ADDR(.data.patch.rse) - LOAD_OFFSET)
 159         {
 160           __start___rse_patchlist = .;
 161           *(.data.patch.rse)
 162           __end___rse_patchlist = .;
 163         }
 164
 165   .data.patch.mckinley_e9 : AT(ADDR(.data.patch.mckinley_e9) - LOAD_OFFSET)
 166         {
 167           __start___mckinley_e9_bundles = .;
 168           *(.data.patch.mckinley_e9)
 169           __end___mckinley_e9_bundles = .;
 170         }
 171
 172 #if defined(CONFIG_IA64_GENERIC)
 173   /* Machine Vector */
 174   . = ALIGN(16);
 175   .machvec : AT(ADDR(.machvec) - LOAD_OFFSET)
 176         {
 177           machvec_start = .;
 178           *(.machvec)
 179           machvec_end = .;
 180         }
 181 #endif
 182
 183   . = ALIGN(8);
 184    __con_initcall_start = .;
 185   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET)
 186         { *(.con_initcall.init) }
 187   __con_initcall_end = .;
 188   __security_initcall_start = .;
 189   .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET)
 190         { *(.security_initcall.init) }
 191   __security_initcall_end = .;
 192   . = ALIGN(PAGE_SIZE);
 193   __init_end = .;
 194
 195   /* The initial task and kernel stack */
 196   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET)
 197         { *(.data.init_task) }
 198
 199   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET)
 200         { *(__special_page_section)
 201           __start_gate_section = .;
 202           *(.data.gate)
 203           __stop_gate_section = .;
 204         }
 205   . = ALIGN(PAGE_SIZE);         /* make sure the gate page doesn't expose
 206                                  * kernel data
 207                                  */
 208
 209   .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET)
 210         { *(.data.read_mostly) }
 211
 212   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET)
 213         { *(.data.cacheline_aligned) }
 214
 215   /* Per-cpu data: */
 216   percpu : { } :percpu
 217   . = ALIGN(PERCPU_PAGE_SIZE);
 218   __phys_per_cpu_start = .;
 219   .data.percpu PERCPU_ADDR : AT(__phys_per_cpu_start - LOAD_OFFSET)
 220         {
 221                 __per_cpu_start = .;
 222                 *(.data.percpu)
 223                 *(.data.percpu.shared_aligned)
 224                 __per_cpu_end = .;
 225         }
 226   . = __phys_per_cpu_start + PERCPU_PAGE_SIZE;  /* ensure percpu data fits
 227                                                  * into percpu page size
 228                                                  */
 229
 230   data : { } :data
 231   .data : AT(ADDR(.data) - LOAD_OFFSET)
 232         {
 233                 DATA_DATA
 234                 *(.data1)
 235                 *(.gnu.linkonce.d*)
 236                 CONSTRUCTORS
 237         }
 238
 239   . = ALIGN(16);        /* gp must be 16-byte aligned for exc. table */
 240   .got : AT(ADDR(.got) - LOAD_OFFSET)
 241         { *(.got.plt) *(.got) }
 242   __gp = ADDR(.got) + 0x200000;
 243   /* We want the small data sections together, so single-instruction offsets
 244      can access them all, and initialized data all before uninitialized, so
 245      we can shorten the on-disk segment size.  */
 246   .sdata : AT(ADDR(.sdata) - LOAD_OFFSET)
 247         { *(.sdata) *(.sdata1) *(.srdata) }
 248   _edata  =  .;
 249   __bss_start = .;
 250   .sbss : AT(ADDR(.sbss) - LOAD_OFFSET)
 251         { *(.sbss) *(.scommon) }
 252   .bss : AT(ADDR(.bss) - LOAD_OFFSET)
 253         { *(.bss) *(COMMON) }
 254   __bss_stop = .;
 255
 256   _end = .;
 257
 258   code : { } :code
 259   /* Stabs debugging sections.  */
 260   .stab 0 : { *(.stab) }
 261   .stabstr 0 : { *(.stabstr) }
 262   .stab.excl 0 : { *(.stab.excl) }
 263   .stab.exclstr 0 : { *(.stab.exclstr) }
 264   .stab.index 0 : { *(.stab.index) }
 265   .stab.indexstr 0 : { *(.stab.indexstr) }
 266   /* DWARF debug sections.
 267      Symbols in the DWARF debugging sections are relative to the beginning
 268      of the section so we begin them at 0.  */
 269   /* DWARF 1 */
 270   .debug          0 : { *(.debug) }
 271   .line           0 : { *(.line) }
 272   /* GNU DWARF 1 extensions */
 273   .debug_srcinfo  0 : { *(.debug_srcinfo) }
 274   .debug_sfnames  0 : { *(.debug_sfnames) }
 275   /* DWARF 1.1 and DWARF 2 */
 276   .debug_aranges  0 : { *(.debug_aranges) }
 277   .debug_pubnames 0 : { *(.debug_pubnames) }
 278   /* DWARF 2 */
 279   .debug_info     0 : { *(.debug_info) }
 280   .debug_abbrev   0 : { *(.debug_abbrev) }
 281   .debug_line     0 : { *(.debug_line) }
 282   .debug_frame    0 : { *(.debug_frame) }
 283   .debug_str      0 : { *(.debug_str) }
 284   .debug_loc      0 : { *(.debug_loc) }
 285   .debug_macinfo  0 : { *(.debug_macinfo) }
 286   /* SGI/MIPS DWARF 2 extensions */
 287   .debug_weaknames 0 : { *(.debug_weaknames) }
 288   .debug_funcnames 0 : { *(.debug_funcnames) }
 289   .debug_typenames 0 : { *(.debug_typenames) }
 290   .debug_varnames  0 : { *(.debug_varnames) }
 291   /* These must appear regardless of  .  */
 292   /DISCARD/ : { *(.comment) }
 293   /DISCARD/ : { *(.note) }
 294 }