err.no Git - linux-2.6/blob - arch/i386/kernel/entry.S

   1 /*
   2  *  linux/arch/i386/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  */
   6
   7 /*
   8  * entry.S contains the system-call and fault low-level handling routines.
   9  * This also contains the timer-interrupt handler, as well as all interrupts
  10  * and faults that can result in a task-switch.
  11  *
  12  * NOTE: This code handles signal-recognition, which happens every time
  13  * after a timer-interrupt and after each system call.
  14  *
  15  * I changed all the .align's to 4 (16 byte alignment), as that's faster
  16  * on a 486.
  17  *
  18  * Stack layout in 'ret_from_system_call':
  19  *      ptrace needs to have all regs on the stack.
  20  *      if the order here is changed, it needs to be
  21  *      updated in fork.c:copy_process, signal.c:do_signal,
  22  *      ptrace.c and ptrace.h
  23  *
  24  *       0(%esp) - %ebx
  25  *       4(%esp) - %ecx
  26  *       8(%esp) - %edx
  27  *       C(%esp) - %esi
  28  *      10(%esp) - %edi
  29  *      14(%esp) - %ebp
  30  *      18(%esp) - %eax
  31  *      1C(%esp) - %ds
  32  *      20(%esp) - %es
  33  *      24(%esp) - %gs
  34  *      28(%esp) - orig_eax
  35  *      2C(%esp) - %eip
  36  *      30(%esp) - %cs
  37  *      34(%esp) - %eflags
  38  *      38(%esp) - %oldesp
  39  *      3C(%esp) - %oldss
  40  *
  41  * "current" is in register %ebx during any slow entries.
  42  */
  43
  44 #include <linux/linkage.h>
  45 #include <asm/thread_info.h>
  46 #include <asm/irqflags.h>
  47 #include <asm/errno.h>
  48 #include <asm/segment.h>
  49 #include <asm/smp.h>
  50 #include <asm/page.h>
  51 #include <asm/desc.h>
  52 #include <asm/percpu.h>
  53 #include <asm/dwarf2.h>
  54 #include "irq_vectors.h"
  55
  56 #define nr_syscalls ((syscall_table_size)/4)
  57
  58 CF_MASK         = 0x00000001
  59 TF_MASK         = 0x00000100
  60 IF_MASK         = 0x00000200
  61 DF_MASK         = 0x00000400
  62 NT_MASK         = 0x00004000
  63 VM_MASK         = 0x00020000
  64
  65 /* These are replaces for paravirtualization */
  66 #define DISABLE_INTERRUPTS              cli
  67 #define ENABLE_INTERRUPTS               sti
  68 #define ENABLE_INTERRUPTS_SYSEXIT       sti; sysexit
  69 #define INTERRUPT_RETURN                iret
  70 #define GET_CR0_INTO_EAX                movl %cr0, %eax
  71
  72 #ifdef CONFIG_PREEMPT
  73 #define preempt_stop            DISABLE_INTERRUPTS; TRACE_IRQS_OFF
  74 #else
  75 #define preempt_stop
  76 #define resume_kernel           restore_nocheck
  77 #endif
  78
  79 .macro TRACE_IRQS_IRET
  80 #ifdef CONFIG_TRACE_IRQFLAGS
  81         testl $IF_MASK,PT_EFLAGS(%esp)     # interrupts off?
  82         jz 1f
  83         TRACE_IRQS_ON
  84 1:
  85 #endif
  86 .endm
  87
  88 #ifdef CONFIG_VM86
  89 #define resume_userspace_sig    check_userspace
  90 #else
  91 #define resume_userspace_sig    resume_userspace
  92 #endif
  93
  94 #define SAVE_ALL \
  95         cld; \
  96         pushl %gs; \
  97         CFI_ADJUST_CFA_OFFSET 4;\
  98         /*CFI_REL_OFFSET gs, 0;*/\
  99         pushl %es; \
 100         CFI_ADJUST_CFA_OFFSET 4;\
 101         /*CFI_REL_OFFSET es, 0;*/\
 102         pushl %ds; \
 103         CFI_ADJUST_CFA_OFFSET 4;\
 104         /*CFI_REL_OFFSET ds, 0;*/\
 105         pushl %eax; \
 106         CFI_ADJUST_CFA_OFFSET 4;\
 107         CFI_REL_OFFSET eax, 0;\
 108         pushl %ebp; \
 109         CFI_ADJUST_CFA_OFFSET 4;\
 110         CFI_REL_OFFSET ebp, 0;\
 111         pushl %edi; \
 112         CFI_ADJUST_CFA_OFFSET 4;\
 113         CFI_REL_OFFSET edi, 0;\
 114         pushl %esi; \
 115         CFI_ADJUST_CFA_OFFSET 4;\
 116         CFI_REL_OFFSET esi, 0;\
 117         pushl %edx; \
 118         CFI_ADJUST_CFA_OFFSET 4;\
 119         CFI_REL_OFFSET edx, 0;\
 120         pushl %ecx; \
 121         CFI_ADJUST_CFA_OFFSET 4;\
 122         CFI_REL_OFFSET ecx, 0;\
 123         pushl %ebx; \
 124         CFI_ADJUST_CFA_OFFSET 4;\
 125         CFI_REL_OFFSET ebx, 0;\
 126         movl $(__USER_DS), %edx; \
 127         movl %edx, %ds; \
 128         movl %edx, %es; \
 129         movl $(__KERNEL_PDA), %edx; \
 130         movl %edx, %gs
 131
 132 #define RESTORE_INT_REGS \
 133         popl %ebx;      \
 134         CFI_ADJUST_CFA_OFFSET -4;\
 135         CFI_RESTORE ebx;\
 136         popl %ecx;      \
 137         CFI_ADJUST_CFA_OFFSET -4;\
 138         CFI_RESTORE ecx;\
 139         popl %edx;      \
 140         CFI_ADJUST_CFA_OFFSET -4;\
 141         CFI_RESTORE edx;\
 142         popl %esi;      \
 143         CFI_ADJUST_CFA_OFFSET -4;\
 144         CFI_RESTORE esi;\
 145         popl %edi;      \
 146         CFI_ADJUST_CFA_OFFSET -4;\
 147         CFI_RESTORE edi;\
 148         popl %ebp;      \
 149         CFI_ADJUST_CFA_OFFSET -4;\
 150         CFI_RESTORE ebp;\
 151         popl %eax;      \
 152         CFI_ADJUST_CFA_OFFSET -4;\
 153         CFI_RESTORE eax
 154
 155 #define RESTORE_REGS    \
 156         RESTORE_INT_REGS; \
 157 1:      popl %ds;       \
 158         CFI_ADJUST_CFA_OFFSET -4;\
 159         /*CFI_RESTORE ds;*/\
 160 2:      popl %es;       \
 161         CFI_ADJUST_CFA_OFFSET -4;\
 162         /*CFI_RESTORE es;*/\
 163 3:      popl %gs;       \
 164         CFI_ADJUST_CFA_OFFSET -4;\
 165         /*CFI_RESTORE gs;*/\
 166 .pushsection .fixup,"ax";       \
 167 4:      movl $0,(%esp); \
 168         jmp 1b;         \
 169 5:      movl $0,(%esp); \
 170         jmp 2b;         \
 171 6:      movl $0,(%esp); \
 172         jmp 3b;         \
 173 .section __ex_table,"a";\
 174         .align 4;       \
 175         .long 1b,4b;    \
 176         .long 2b,5b;    \
 177         .long 3b,6b;    \
 178 .popsection
 179
 180 #define RING0_INT_FRAME \
 181         CFI_STARTPROC simple;\
 182         CFI_SIGNAL_FRAME;\
 183         CFI_DEF_CFA esp, 3*4;\
 184         /*CFI_OFFSET cs, -2*4;*/\
 185         CFI_OFFSET eip, -3*4
 186
 187 #define RING0_EC_FRAME \
 188         CFI_STARTPROC simple;\
 189         CFI_SIGNAL_FRAME;\
 190         CFI_DEF_CFA esp, 4*4;\
 191         /*CFI_OFFSET cs, -2*4;*/\
 192         CFI_OFFSET eip, -3*4
 193
 194 #define RING0_PTREGS_FRAME \
 195         CFI_STARTPROC simple;\
 196         CFI_SIGNAL_FRAME;\
 197         CFI_DEF_CFA esp, PT_OLDESP-PT_EBX;\
 198         /*CFI_OFFSET cs, PT_CS-PT_OLDESP;*/\
 199         CFI_OFFSET eip, PT_EIP-PT_OLDESP;\
 200         /*CFI_OFFSET es, PT_ES-PT_OLDESP;*/\
 201         /*CFI_OFFSET ds, PT_DS-PT_OLDESP;*/\
 202         CFI_OFFSET eax, PT_EAX-PT_OLDESP;\
 203         CFI_OFFSET ebp, PT_EBP-PT_OLDESP;\
 204         CFI_OFFSET edi, PT_EDI-PT_OLDESP;\
 205         CFI_OFFSET esi, PT_ESI-PT_OLDESP;\
 206         CFI_OFFSET edx, PT_EDX-PT_OLDESP;\
 207         CFI_OFFSET ecx, PT_ECX-PT_OLDESP;\
 208         CFI_OFFSET ebx, PT_EBX-PT_OLDESP
 209
 210 ENTRY(ret_from_fork)
 211         CFI_STARTPROC
 212         pushl %eax
 213         CFI_ADJUST_CFA_OFFSET 4
 214         call schedule_tail
 215         GET_THREAD_INFO(%ebp)
 216         popl %eax
 217         CFI_ADJUST_CFA_OFFSET -4
 218         pushl $0x0202                   # Reset kernel eflags
 219         CFI_ADJUST_CFA_OFFSET 4
 220         popfl
 221         CFI_ADJUST_CFA_OFFSET -4
 222         jmp syscall_exit
 223         CFI_ENDPROC
 224
 225 /*
 226  * Return to user mode is not as complex as all this looks,
 227  * but we want the default path for a system call return to
 228  * go as quickly as possible which is why some of this is
 229  * less clear than it otherwise should be.
 230  */
 231
 232         # userspace resumption stub bypassing syscall exit tracing
 233         ALIGN
 234         RING0_PTREGS_FRAME
 235 ret_from_exception:
 236         preempt_stop
 237 ret_from_intr:
 238         GET_THREAD_INFO(%ebp)
 239 check_userspace:
 240         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS and CS
 241         movb PT_CS(%esp), %al
 242         andl $(VM_MASK | SEGMENT_RPL_MASK), %eax
 243         cmpl $USER_RPL, %eax
 244         jb resume_kernel                # not returning to v8086 or userspace
 245
 246 ENTRY(resume_userspace)
 247         DISABLE_INTERRUPTS              # make sure we don't miss an interrupt
 248                                         # setting need_resched or sigpending
 249                                         # between sampling and the iret
 250         movl TI_flags(%ebp), %ecx
 251         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done on
 252                                         # int/exception return?
 253         jne work_pending
 254         jmp restore_all
 255
 256 #ifdef CONFIG_PREEMPT
 257 ENTRY(resume_kernel)
 258         DISABLE_INTERRUPTS
 259         cmpl $0,TI_preempt_count(%ebp)  # non-zero preempt_count ?
 260         jnz restore_nocheck
 261 need_resched:
 262         movl TI_flags(%ebp), %ecx       # need_resched set ?
 263         testb $_TIF_NEED_RESCHED, %cl
 264         jz restore_all
 265         testl $IF_MASK,PT_EFLAGS(%esp)  # interrupts off (exception path) ?
 266         jz restore_all
 267         call preempt_schedule_irq
 268         jmp need_resched
 269 #endif
 270         CFI_ENDPROC
 271
 272 /* SYSENTER_RETURN points to after the "sysenter" instruction in
 273    the vsyscall page.  See vsyscall-sysentry.S, which defines the symbol.  */
 274
 275         # sysenter call handler stub
 276 ENTRY(sysenter_entry)
 277         CFI_STARTPROC simple
 278         CFI_SIGNAL_FRAME
 279         CFI_DEF_CFA esp, 0
 280         CFI_REGISTER esp, ebp
 281         movl TSS_sysenter_esp0(%esp),%esp
 282 sysenter_past_esp:
 283         /*
 284          * No need to follow this irqs on/off section: the syscall
 285          * disabled irqs and here we enable it straight after entry:
 286          */
 287         ENABLE_INTERRUPTS
 288         pushl $(__USER_DS)
 289         CFI_ADJUST_CFA_OFFSET 4
 290         /*CFI_REL_OFFSET ss, 0*/
 291         pushl %ebp
 292         CFI_ADJUST_CFA_OFFSET 4
 293         CFI_REL_OFFSET esp, 0
 294         pushfl
 295         CFI_ADJUST_CFA_OFFSET 4
 296         pushl $(__USER_CS)
 297         CFI_ADJUST_CFA_OFFSET 4
 298         /*CFI_REL_OFFSET cs, 0*/
 299         /*
 300          * Push current_thread_info()->sysenter_return to the stack.
 301          * A tiny bit of offset fixup is necessary - 4*4 means the 4 words
 302          * pushed above; +8 corresponds to copy_thread's esp0 setting.
 303          */
 304         pushl (TI_sysenter_return-THREAD_SIZE+8+4*4)(%esp)
 305         CFI_ADJUST_CFA_OFFSET 4
 306         CFI_REL_OFFSET eip, 0
 307
 308 /*
 309  * Load the potential sixth argument from user stack.
 310  * Careful about security.
 311  */
 312         cmpl $__PAGE_OFFSET-3,%ebp
 313         jae syscall_fault
 314 1:      movl (%ebp),%ebp
 315 .section __ex_table,"a"
 316         .align 4
 317         .long 1b,syscall_fault
 318 .previous
 319
 320         pushl %eax
 321         CFI_ADJUST_CFA_OFFSET 4
 322         SAVE_ALL
 323         GET_THREAD_INFO(%ebp)
 324
 325         /* Note, _TIF_SECCOMP is bit number 8, and so it needs testw and not testb */
 326         testw $(_TIF_SYSCALL_EMU|_TIF_SYSCALL_TRACE|_TIF_SECCOMP|_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
 327         jnz syscall_trace_entry
 328         cmpl $(nr_syscalls), %eax
 329         jae syscall_badsys
 330         call *sys_call_table(,%eax,4)
 331         movl %eax,PT_EAX(%esp)
 332         DISABLE_INTERRUPTS
 333         TRACE_IRQS_OFF
 334         movl TI_flags(%ebp), %ecx
 335         testw $_TIF_ALLWORK_MASK, %cx
 336         jne syscall_exit_work
 337 /* if something modifies registers it must also disable sysexit */
 338         movl PT_EIP(%esp), %edx
 339         movl PT_OLDESP(%esp), %ecx
 340         xorl %ebp,%ebp
 341         TRACE_IRQS_ON
 342 1:      mov  PT_GS(%esp), %gs
 343         ENABLE_INTERRUPTS_SYSEXIT
 344         CFI_ENDPROC
 345 .pushsection .fixup,"ax"
 346 2:      movl $0,PT_GS(%esp)
 347         jmp 1b
 348 .section __ex_table,"a"
 349         .align 4
 350         .long 1b,2b
 351 .popsection
 352
 353         # system call handler stub
 354 ENTRY(system_call)
 355         RING0_INT_FRAME                 # can't unwind into user space anyway
 356         pushl %eax                      # save orig_eax
 357         CFI_ADJUST_CFA_OFFSET 4
 358         SAVE_ALL
 359         GET_THREAD_INFO(%ebp)
 360         testl $TF_MASK,PT_EFLAGS(%esp)
 361         jz no_singlestep
 362         orl $_TIF_SINGLESTEP,TI_flags(%ebp)
 363 no_singlestep:
 364                                         # system call tracing in operation / emulation
 365         /* Note, _TIF_SECCOMP is bit number 8, and so it needs testw and not testb */
 366         testw $(_TIF_SYSCALL_EMU|_TIF_SYSCALL_TRACE|_TIF_SECCOMP|_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
 367         jnz syscall_trace_entry
 368         cmpl $(nr_syscalls), %eax
 369         jae syscall_badsys
 370 syscall_call:
 371         call *sys_call_table(,%eax,4)
 372         movl %eax,PT_EAX(%esp)          # store the return value
 373 syscall_exit:
 374         DISABLE_INTERRUPTS              # make sure we don't miss an interrupt
 375                                         # setting need_resched or sigpending
 376                                         # between sampling and the iret
 377         TRACE_IRQS_OFF
 378         movl TI_flags(%ebp), %ecx
 379         testw $_TIF_ALLWORK_MASK, %cx   # current->work
 380         jne syscall_exit_work
 381
 382 restore_all:
 383         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS, SS and CS
 384         # Warning: PT_OLDSS(%esp) contains the wrong/random values if we
 385         # are returning to the kernel.
 386         # See comments in process.c:copy_thread() for details.
 387         movb PT_OLDSS(%esp), %ah
 388         movb PT_CS(%esp), %al
 389         andl $(VM_MASK | (SEGMENT_TI_MASK << 8) | SEGMENT_RPL_MASK), %eax
 390         cmpl $((SEGMENT_LDT << 8) | USER_RPL), %eax
 391         CFI_REMEMBER_STATE
 392         je ldt_ss                       # returning to user-space with LDT SS
 393 restore_nocheck:
 394         TRACE_IRQS_IRET
 395 restore_nocheck_notrace:
 396         RESTORE_REGS
 397         addl $4, %esp                   # skip orig_eax/error_code
 398         CFI_ADJUST_CFA_OFFSET -4
 399 1:      INTERRUPT_RETURN
 400 .section .fixup,"ax"
 401 iret_exc:
 402         TRACE_IRQS_ON
 403         ENABLE_INTERRUPTS
 404         pushl $0                        # no error code
 405         pushl $do_iret_error
 406         jmp error_code
 407 .previous
 408 .section __ex_table,"a"
 409         .align 4
 410         .long 1b,iret_exc
 411 .previous
 412
 413         CFI_RESTORE_STATE
 414 ldt_ss:
 415         larl PT_OLDSS(%esp), %eax
 416         jnz restore_nocheck
 417         testl $0x00400000, %eax         # returning to 32bit stack?
 418         jnz restore_nocheck             # allright, normal return
 419         /* If returning to userspace with 16bit stack,
 420          * try to fix the higher word of ESP, as the CPU
 421          * won't restore it.
 422          * This is an "official" bug of all the x86-compatible
 423          * CPUs, which we can try to work around to make
 424          * dosemu and wine happy. */
 425         movl PT_OLDESP(%esp), %eax
 426         movl %esp, %edx
 427         call patch_espfix_desc
 428         pushl $__ESPFIX_SS
 429         CFI_ADJUST_CFA_OFFSET 4
 430         pushl %eax
 431         CFI_ADJUST_CFA_OFFSET 4
 432         DISABLE_INTERRUPTS
 433         TRACE_IRQS_OFF
 434         lss (%esp), %esp
 435         CFI_ADJUST_CFA_OFFSET -8
 436         jmp restore_nocheck
 437         CFI_ENDPROC
 438
 439         # perform work that needs to be done immediately before resumption
 440         ALIGN
 441         RING0_PTREGS_FRAME              # can't unwind into user space anyway
 442 work_pending:
 443         testb $_TIF_NEED_RESCHED, %cl
 444         jz work_notifysig
 445 work_resched:
 446         call schedule
 447         DISABLE_INTERRUPTS              # make sure we don't miss an interrupt
 448                                         # setting need_resched or sigpending
 449                                         # between sampling and the iret
 450         TRACE_IRQS_OFF
 451         movl TI_flags(%ebp), %ecx
 452         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done other
 453                                         # than syscall tracing?
 454         jz restore_all
 455         testb $_TIF_NEED_RESCHED, %cl
 456         jnz work_resched
 457
 458 work_notifysig:                         # deal with pending signals and
 459                                         # notify-resume requests
 460         testl $VM_MASK, PT_EFLAGS(%esp)
 461         movl %esp, %eax
 462         jne work_notifysig_v86          # returning to kernel-space or
 463                                         # vm86-space
 464         xorl %edx, %edx
 465         call do_notify_resume
 466         jmp resume_userspace_sig
 467
 468         ALIGN
 469 work_notifysig_v86:
 470 #ifdef CONFIG_VM86
 471         pushl %ecx                      # save ti_flags for do_notify_resume
 472         CFI_ADJUST_CFA_OFFSET 4
 473         call save_v86_state             # %eax contains pt_regs pointer
 474         popl %ecx
 475         CFI_ADJUST_CFA_OFFSET -4
 476         movl %eax, %esp
 477         xorl %edx, %edx
 478         call do_notify_resume
 479         jmp resume_userspace_sig
 480 #endif
 481
 482         # perform syscall exit tracing
 483         ALIGN
 484 syscall_trace_entry:
 485         movl $-ENOSYS,PT_EAX(%esp)
 486         movl %esp, %eax
 487         xorl %edx,%edx
 488         call do_syscall_trace
 489         cmpl $0, %eax
 490         jne resume_userspace            # ret != 0 -> running under PTRACE_SYSEMU,
 491                                         # so must skip actual syscall
 492         movl PT_ORIG_EAX(%esp), %eax
 493         cmpl $(nr_syscalls), %eax
 494         jnae syscall_call
 495         jmp syscall_exit
 496
 497         # perform syscall exit tracing
 498         ALIGN
 499 syscall_exit_work:
 500         testb $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SINGLESTEP), %cl
 501         jz work_pending
 502         TRACE_IRQS_ON
 503         ENABLE_INTERRUPTS               # could let do_syscall_trace() call
 504                                         # schedule() instead
 505         movl %esp, %eax
 506         movl $1, %edx
 507         call do_syscall_trace
 508         jmp resume_userspace
 509         CFI_ENDPROC
 510
 511         RING0_INT_FRAME                 # can't unwind into user space anyway
 512 syscall_fault:
 513         pushl %eax                      # save orig_eax
 514         CFI_ADJUST_CFA_OFFSET 4
 515         SAVE_ALL
 516         GET_THREAD_INFO(%ebp)
 517         movl $-EFAULT,PT_EAX(%esp)
 518         jmp resume_userspace
 519
 520 syscall_badsys:
 521         movl $-ENOSYS,PT_EAX(%esp)
 522         jmp resume_userspace
 523         CFI_ENDPROC
 524
 525 #define FIXUP_ESPFIX_STACK \
 526         /* since we are on a wrong stack, we cant make it a C code :( */ \
 527         GET_THREAD_INFO(%ebp); \
 528         movl TI_cpu(%ebp), %ebx; \
 529         PER_CPU(cpu_gdt_descr, %ebx); \
 530         movl GDS_address(%ebx), %ebx; \
 531         GET_DESC_BASE(GDT_ENTRY_ESPFIX_SS, %ebx, %eax, %ax, %al, %ah); \
 532         addl %esp, %eax; \
 533         pushl $__KERNEL_DS; \
 534         CFI_ADJUST_CFA_OFFSET 4; \
 535         pushl %eax; \
 536         CFI_ADJUST_CFA_OFFSET 4; \
 537         lss (%esp), %esp; \
 538         CFI_ADJUST_CFA_OFFSET -8;
 539 #define UNWIND_ESPFIX_STACK \
 540         movl %ss, %eax; \
 541         /* see if on espfix stack */ \
 542         cmpw $__ESPFIX_SS, %ax; \
 543         jne 27f; \
 544         movl $__KERNEL_DS, %eax; \
 545         movl %eax, %ds; \
 546         movl %eax, %es; \
 547         /* switch to normal stack */ \
 548         FIXUP_ESPFIX_STACK; \
 549 27:;
 550
 551 /*
 552  * Build the entry stubs and pointer table with
 553  * some assembler magic.
 554  */
 555 .data
 556 ENTRY(interrupt)
 557 .text
 558
 559 vector=0
 560 ENTRY(irq_entries_start)
 561         RING0_INT_FRAME
 562 .rept NR_IRQS
 563         ALIGN
 564  .if vector
 565         CFI_ADJUST_CFA_OFFSET -4
 566  .endif
 567 1:      pushl $~(vector)
 568         CFI_ADJUST_CFA_OFFSET 4
 569         jmp common_interrupt
 570 .data
 571         .long 1b
 572 .text
 573 vector=vector+1
 574 .endr
 575
 576 /*
 577  * the CPU automatically disables interrupts when executing an IRQ vector,
 578  * so IRQ-flags tracing has to follow that:
 579  */
 580         ALIGN
 581 common_interrupt:
 582         SAVE_ALL
 583         TRACE_IRQS_OFF
 584         movl %esp,%eax
 585         call do_IRQ
 586         jmp ret_from_intr
 587         CFI_ENDPROC
 588
 589 #define BUILD_INTERRUPT(name, nr)       \
 590 ENTRY(name)                             \
 591         RING0_INT_FRAME;                \
 592         pushl $~(nr);                   \
 593         CFI_ADJUST_CFA_OFFSET 4;        \
 594         SAVE_ALL;                       \
 595         TRACE_IRQS_OFF                  \
 596         movl %esp,%eax;                 \
 597         call smp_/**/name;              \
 598         jmp ret_from_intr;              \
 599         CFI_ENDPROC
 600
 601 /* The include is where all of the SMP etc. interrupts come from */
 602 #include "entry_arch.h"
 603
 604 KPROBE_ENTRY(page_fault)
 605         RING0_EC_FRAME
 606         pushl $do_page_fault
 607         CFI_ADJUST_CFA_OFFSET 4
 608         ALIGN
 609 error_code:
 610         /* the function address is in %gs's slot on the stack */
 611         pushl %es
 612         CFI_ADJUST_CFA_OFFSET 4
 613         /*CFI_REL_OFFSET es, 0*/
 614         pushl %ds
 615         CFI_ADJUST_CFA_OFFSET 4
 616         /*CFI_REL_OFFSET ds, 0*/
 617         pushl %eax
 618         CFI_ADJUST_CFA_OFFSET 4
 619         CFI_REL_OFFSET eax, 0
 620         pushl %ebp
 621         CFI_ADJUST_CFA_OFFSET 4
 622         CFI_REL_OFFSET ebp, 0
 623         pushl %edi
 624         CFI_ADJUST_CFA_OFFSET 4
 625         CFI_REL_OFFSET edi, 0
 626         pushl %esi
 627         CFI_ADJUST_CFA_OFFSET 4
 628         CFI_REL_OFFSET esi, 0
 629         pushl %edx
 630         CFI_ADJUST_CFA_OFFSET 4
 631         CFI_REL_OFFSET edx, 0
 632         pushl %ecx
 633         CFI_ADJUST_CFA_OFFSET 4
 634         CFI_REL_OFFSET ecx, 0
 635         pushl %ebx
 636         CFI_ADJUST_CFA_OFFSET 4
 637         CFI_REL_OFFSET ebx, 0
 638         cld
 639         pushl %gs
 640         CFI_ADJUST_CFA_OFFSET 4
 641         /*CFI_REL_OFFSET gs, 0*/
 642         movl $(__KERNEL_PDA), %ecx
 643         movl %ecx, %gs
 644         UNWIND_ESPFIX_STACK
 645         popl %ecx
 646         CFI_ADJUST_CFA_OFFSET -4
 647         /*CFI_REGISTER es, ecx*/
 648         movl PT_GS(%esp), %edi          # get the function address
 649         movl PT_ORIG_EAX(%esp), %edx    # get the error code
 650         movl $-1, PT_ORIG_EAX(%esp)     # no syscall to restart
 651         mov  %ecx, PT_GS(%esp)
 652         /*CFI_REL_OFFSET gs, ES*/
 653         movl $(__USER_DS), %ecx
 654         movl %ecx, %ds
 655         movl %ecx, %es
 656         movl %esp,%eax                  # pt_regs pointer
 657         call *%edi
 658         jmp ret_from_exception
 659         CFI_ENDPROC
 660 KPROBE_END(page_fault)
 661
 662 ENTRY(coprocessor_error)
 663         RING0_INT_FRAME
 664         pushl $0
 665         CFI_ADJUST_CFA_OFFSET 4
 666         pushl $do_coprocessor_error
 667         CFI_ADJUST_CFA_OFFSET 4
 668         jmp error_code
 669         CFI_ENDPROC
 670
 671 ENTRY(simd_coprocessor_error)
 672         RING0_INT_FRAME
 673         pushl $0
 674         CFI_ADJUST_CFA_OFFSET 4
 675         pushl $do_simd_coprocessor_error
 676         CFI_ADJUST_CFA_OFFSET 4
 677         jmp error_code
 678         CFI_ENDPROC
 679
 680 ENTRY(device_not_available)
 681         RING0_INT_FRAME
 682         pushl $-1                       # mark this as an int
 683         CFI_ADJUST_CFA_OFFSET 4
 684         SAVE_ALL
 685         GET_CR0_INTO_EAX
 686         testl $0x4, %eax                # EM (math emulation bit)
 687         jne device_not_available_emulate
 688         preempt_stop
 689         call math_state_restore
 690         jmp ret_from_exception
 691 device_not_available_emulate:
 692         pushl $0                        # temporary storage for ORIG_EIP
 693         CFI_ADJUST_CFA_OFFSET 4
 694         call math_emulate
 695         addl $4, %esp
 696         CFI_ADJUST_CFA_OFFSET -4
 697         jmp ret_from_exception
 698         CFI_ENDPROC
 699
 700 /*
 701  * Debug traps and NMI can happen at the one SYSENTER instruction
 702  * that sets up the real kernel stack. Check here, since we can't
 703  * allow the wrong stack to be used.
 704  *
 705  * "TSS_sysenter_esp0+12" is because the NMI/debug handler will have
 706  * already pushed 3 words if it hits on the sysenter instruction:
 707  * eflags, cs and eip.
 708  *
 709  * We just load the right stack, and push the three (known) values
 710  * by hand onto the new stack - while updating the return eip past
 711  * the instruction that would have done it for sysenter.
 712  */
 713 #define FIX_STACK(offset, ok, label)            \
 714         cmpw $__KERNEL_CS,4(%esp);              \
 715         jne ok;                                 \
 716 label:                                          \
 717         movl TSS_sysenter_esp0+offset(%esp),%esp;       \
 718         CFI_DEF_CFA esp, 0;                     \
 719         CFI_UNDEFINED eip;                      \
 720         pushfl;                                 \
 721         CFI_ADJUST_CFA_OFFSET 4;                \
 722         pushl $__KERNEL_CS;                     \
 723         CFI_ADJUST_CFA_OFFSET 4;                \
 724         pushl $sysenter_past_esp;               \
 725         CFI_ADJUST_CFA_OFFSET 4;                \
 726         CFI_REL_OFFSET eip, 0
 727
 728 KPROBE_ENTRY(debug)
 729         RING0_INT_FRAME
 730         cmpl $sysenter_entry,(%esp)
 731         jne debug_stack_correct
 732         FIX_STACK(12, debug_stack_correct, debug_esp_fix_insn)
 733 debug_stack_correct:
 734         pushl $-1                       # mark this as an int
 735         CFI_ADJUST_CFA_OFFSET 4
 736         SAVE_ALL
 737         xorl %edx,%edx                  # error code 0
 738         movl %esp,%eax                  # pt_regs pointer
 739         call do_debug
 740         jmp ret_from_exception
 741         CFI_ENDPROC
 742 KPROBE_END(debug)
 743
 744 /*
 745  * NMI is doubly nasty. It can happen _while_ we're handling
 746  * a debug fault, and the debug fault hasn't yet been able to
 747  * clear up the stack. So we first check whether we got  an
 748  * NMI on the sysenter entry path, but after that we need to
 749  * check whether we got an NMI on the debug path where the debug
 750  * fault happened on the sysenter path.
 751  */
 752 KPROBE_ENTRY(nmi)
 753         RING0_INT_FRAME
 754         pushl %eax
 755         CFI_ADJUST_CFA_OFFSET 4
 756         movl %ss, %eax
 757         cmpw $__ESPFIX_SS, %ax
 758         popl %eax
 759         CFI_ADJUST_CFA_OFFSET -4
 760         je nmi_espfix_stack
 761         cmpl $sysenter_entry,(%esp)
 762         je nmi_stack_fixup
 763         pushl %eax
 764         CFI_ADJUST_CFA_OFFSET 4
 765         movl %esp,%eax
 766         /* Do not access memory above the end of our stack page,
 767          * it might not exist.
 768          */
 769         andl $(THREAD_SIZE-1),%eax
 770         cmpl $(THREAD_SIZE-20),%eax
 771         popl %eax
 772         CFI_ADJUST_CFA_OFFSET -4
 773         jae nmi_stack_correct
 774         cmpl $sysenter_entry,12(%esp)
 775         je nmi_debug_stack_check
 776 nmi_stack_correct:
 777         /* We have a RING0_INT_FRAME here */
 778         pushl %eax
 779         CFI_ADJUST_CFA_OFFSET 4
 780         SAVE_ALL
 781         xorl %edx,%edx          # zero error code
 782         movl %esp,%eax          # pt_regs pointer
 783         call do_nmi
 784         jmp restore_nocheck_notrace
 785         CFI_ENDPROC
 786
 787 nmi_stack_fixup:
 788         RING0_INT_FRAME
 789         FIX_STACK(12,nmi_stack_correct, 1)
 790         jmp nmi_stack_correct
 791
 792 nmi_debug_stack_check:
 793         /* We have a RING0_INT_FRAME here */
 794         cmpw $__KERNEL_CS,16(%esp)
 795         jne nmi_stack_correct
 796         cmpl $debug,(%esp)
 797         jb nmi_stack_correct
 798         cmpl $debug_esp_fix_insn,(%esp)
 799         ja nmi_stack_correct
 800         FIX_STACK(24,nmi_stack_correct, 1)
 801         jmp nmi_stack_correct
 802
 803 nmi_espfix_stack:
 804         /* We have a RING0_INT_FRAME here.
 805          *
 806          * create the pointer to lss back
 807          */
 808         pushl %ss
 809         CFI_ADJUST_CFA_OFFSET 4
 810         pushl %esp
 811         CFI_ADJUST_CFA_OFFSET 4
 812         addw $4, (%esp)
 813         /* copy the iret frame of 12 bytes */
 814         .rept 3
 815         pushl 16(%esp)
 816         CFI_ADJUST_CFA_OFFSET 4
 817         .endr
 818         pushl %eax
 819         CFI_ADJUST_CFA_OFFSET 4
 820         SAVE_ALL
 821         FIXUP_ESPFIX_STACK              # %eax == %esp
 822         xorl %edx,%edx                  # zero error code
 823         call do_nmi
 824         RESTORE_REGS
 825         lss 12+4(%esp), %esp            # back to espfix stack
 826         CFI_ADJUST_CFA_OFFSET -24
 827 1:      INTERRUPT_RETURN
 828         CFI_ENDPROC
 829 .section __ex_table,"a"
 830         .align 4
 831         .long 1b,iret_exc
 832 .previous
 833 KPROBE_END(nmi)
 834
 835 KPROBE_ENTRY(int3)
 836         RING0_INT_FRAME
 837         pushl $-1                       # mark this as an int
 838         CFI_ADJUST_CFA_OFFSET 4
 839         SAVE_ALL
 840         xorl %edx,%edx          # zero error code
 841         movl %esp,%eax          # pt_regs pointer
 842         call do_int3
 843         jmp ret_from_exception
 844         CFI_ENDPROC
 845 KPROBE_END(int3)
 846
 847 ENTRY(overflow)
 848         RING0_INT_FRAME
 849         pushl $0
 850         CFI_ADJUST_CFA_OFFSET 4
 851         pushl $do_overflow
 852         CFI_ADJUST_CFA_OFFSET 4
 853         jmp error_code
 854         CFI_ENDPROC
 855
 856 ENTRY(bounds)
 857         RING0_INT_FRAME
 858         pushl $0
 859         CFI_ADJUST_CFA_OFFSET 4
 860         pushl $do_bounds
 861         CFI_ADJUST_CFA_OFFSET 4
 862         jmp error_code
 863         CFI_ENDPROC
 864
 865 ENTRY(invalid_op)
 866         RING0_INT_FRAME
 867         pushl $0
 868         CFI_ADJUST_CFA_OFFSET 4
 869         pushl $do_invalid_op
 870         CFI_ADJUST_CFA_OFFSET 4
 871         jmp error_code
 872         CFI_ENDPROC
 873
 874 ENTRY(coprocessor_segment_overrun)
 875         RING0_INT_FRAME
 876         pushl $0
 877         CFI_ADJUST_CFA_OFFSET 4
 878         pushl $do_coprocessor_segment_overrun
 879         CFI_ADJUST_CFA_OFFSET 4
 880         jmp error_code
 881         CFI_ENDPROC
 882
 883 ENTRY(invalid_TSS)
 884         RING0_EC_FRAME
 885         pushl $do_invalid_TSS
 886         CFI_ADJUST_CFA_OFFSET 4
 887         jmp error_code
 888         CFI_ENDPROC
 889
 890 ENTRY(segment_not_present)
 891         RING0_EC_FRAME
 892         pushl $do_segment_not_present
 893         CFI_ADJUST_CFA_OFFSET 4
 894         jmp error_code
 895         CFI_ENDPROC
 896
 897 ENTRY(stack_segment)
 898         RING0_EC_FRAME
 899         pushl $do_stack_segment
 900         CFI_ADJUST_CFA_OFFSET 4
 901         jmp error_code
 902         CFI_ENDPROC
 903
 904 KPROBE_ENTRY(general_protection)
 905         RING0_EC_FRAME
 906         pushl $do_general_protection
 907         CFI_ADJUST_CFA_OFFSET 4
 908         jmp error_code
 909         CFI_ENDPROC
 910 KPROBE_END(general_protection)
 911
 912 ENTRY(alignment_check)
 913         RING0_EC_FRAME
 914         pushl $do_alignment_check
 915         CFI_ADJUST_CFA_OFFSET 4
 916         jmp error_code
 917         CFI_ENDPROC
 918
 919 ENTRY(divide_error)
 920         RING0_INT_FRAME
 921         pushl $0                        # no error code
 922         CFI_ADJUST_CFA_OFFSET 4
 923         pushl $do_divide_error
 924         CFI_ADJUST_CFA_OFFSET 4
 925         jmp error_code
 926         CFI_ENDPROC
 927
 928 #ifdef CONFIG_X86_MCE
 929 ENTRY(machine_check)
 930         RING0_INT_FRAME
 931         pushl $0
 932         CFI_ADJUST_CFA_OFFSET 4
 933         pushl machine_check_vector
 934         CFI_ADJUST_CFA_OFFSET 4
 935         jmp error_code
 936         CFI_ENDPROC
 937 #endif
 938
 939 ENTRY(spurious_interrupt_bug)
 940         RING0_INT_FRAME
 941         pushl $0
 942         CFI_ADJUST_CFA_OFFSET 4
 943         pushl $do_spurious_interrupt_bug
 944         CFI_ADJUST_CFA_OFFSET 4
 945         jmp error_code
 946         CFI_ENDPROC
 947
 948 #ifdef CONFIG_STACK_UNWIND
 949 ENTRY(arch_unwind_init_running)
 950         CFI_STARTPROC
 951         movl    4(%esp), %edx
 952         movl    (%esp), %ecx
 953         leal    4(%esp), %eax
 954         movl    %ebx, PT_EBX(%edx)
 955         xorl    %ebx, %ebx
 956         movl    %ebx, PT_ECX(%edx)
 957         movl    %ebx, PT_EDX(%edx)
 958         movl    %esi, PT_ESI(%edx)
 959         movl    %edi, PT_EDI(%edx)
 960         movl    %ebp, PT_EBP(%edx)
 961         movl    %ebx, PT_EAX(%edx)
 962         movl    $__USER_DS, PT_DS(%edx)
 963         movl    $__USER_DS, PT_ES(%edx)
 964         movl    $0, PT_GS(%edx)
 965         movl    %ebx, PT_ORIG_EAX(%edx)
 966         movl    %ecx, PT_EIP(%edx)
 967         movl    12(%esp), %ecx
 968         movl    $__KERNEL_CS, PT_CS(%edx)
 969         movl    %ebx, PT_EFLAGS(%edx)
 970         movl    %eax, PT_OLDESP(%edx)
 971         movl    8(%esp), %eax
 972         movl    %ecx, 8(%esp)
 973         movl    PT_EBX(%edx), %ebx
 974         movl    $__KERNEL_DS, PT_OLDSS(%edx)
 975         jmpl    *%eax
 976         CFI_ENDPROC
 977 ENDPROC(arch_unwind_init_running)
 978 #endif
 979
 980 ENTRY(kernel_thread_helper)
 981         pushl $0                # fake return address for unwinder
 982         CFI_STARTPROC
 983         movl %edx,%eax
 984         push %edx
 985         CFI_ADJUST_CFA_OFFSET 4
 986         call *%ebx
 987         push %eax
 988         CFI_ADJUST_CFA_OFFSET 4
 989         call do_exit
 990         CFI_ENDPROC
 991 ENDPROC(kernel_thread_helper)
 992
 993 .section .rodata,"a"
 994 #include "syscall_table.S"
 995
 996 syscall_table_size=(.-sys_call_table)