err.no Git - linux-2.6/blob - arch/blackfin/mach-bf561/head.S

   1 /*
   2  * File:         arch/blackfin/mach-bf561/head.S
   3  * Based on:     arch/blackfin/mach-bf533/head.S
   4  * Author:
   5  *
   6  * Created:
   7  * Description:  BF561 startup file
   8  *
   9  * Modified:
  10  *               Copyright 2004-2006 Analog Devices Inc.
  11  *
  12  * Bugs:         Enter bugs at http://blackfin.uclinux.org/
  13  *
  14  * This program is free software; you can redistribute it and/or modify
  15  * it under the terms of the GNU General Public License as published by
  16  * the Free Software Foundation; either version 2 of the License, or
  17  * (at your option) any later version.
  18  *
  19  * This program is distributed in the hope that it will be useful,
  20  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  21  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22  * GNU General Public License for more details.
  23  *
  24  * You should have received a copy of the GNU General Public License
  25  * along with this program; if not, see the file COPYING, or write
  26  * to the Free Software Foundation, Inc.,
  27  * 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA
  28  */
  29
  30 #include <linux/linkage.h>
  31 #include <linux/init.h>
  32 #include <asm/blackfin.h>
  33 #include <asm/trace.h>
  34
  35 #if CONFIG_BFIN_KERNEL_CLOCK
  36 #include <asm/mach-common/clocks.h>
  37 #include <asm/mach/mem_init.h>
  38 #endif
  39
  40 .extern ___bss_stop
  41 .extern ___bss_start
  42 .extern _bf53x_relocate_l1_mem
  43
  44 #define INITIAL_STACK   0xFFB01000
  45
  46 __INIT
  47
  48 ENTRY(__start)
  49         /* R0: argument of command line string, passed from uboot, save it */
  50         R7 = R0;
  51         /* Enable Cycle Counter and Nesting Of Interrupts */
  52 #ifdef CONFIG_BFIN_SCRATCH_REG_CYCLES
  53         R0 = SYSCFG_SNEN;
  54 #else
  55         R0 = SYSCFG_SNEN | SYSCFG_CCEN;
  56 #endif
  57         SYSCFG = R0;
  58         R0 = 0;
  59
  60         /* Clear Out All the data and pointer Registers */
  61         R1 = R0;
  62         R2 = R0;
  63         R3 = R0;
  64         R4 = R0;
  65         R5 = R0;
  66         R6 = R0;
  67
  68         P0 = R0;
  69         P1 = R0;
  70         P2 = R0;
  71         P3 = R0;
  72         P4 = R0;
  73         P5 = R0;
  74
  75         LC0 = r0;
  76         LC1 = r0;
  77         L0 = r0;
  78         L1 = r0;
  79         L2 = r0;
  80         L3 = r0;
  81
  82         /* Clear Out All the DAG Registers */
  83         B0 = r0;
  84         B1 = r0;
  85         B2 = r0;
  86         B3 = r0;
  87
  88         I0 = r0;
  89         I1 = r0;
  90         I2 = r0;
  91         I3 = r0;
  92
  93         M0 = r0;
  94         M1 = r0;
  95         M2 = r0;
  96         M3 = r0;
  97
  98         trace_buffer_init(p0,r0);
  99         P0 = R1;
 100         R0 = R1;
 101
 102         /* Turn off the icache */
 103         p0.l = LO(IMEM_CONTROL);
 104         p0.h = HI(IMEM_CONTROL);
 105         R1 = [p0];
 106         R0 = ~ENICPLB;
 107         R0 = R0 & R1;
 108         [p0] = R0;
 109         SSYNC;
 110
 111         /* Turn off the dcache */
 112         p0.l = LO(DMEM_CONTROL);
 113         p0.h = HI(DMEM_CONTROL);
 114         R1 = [p0];
 115         R0 = ~ENDCPLB;
 116         R0 = R0 & R1;
 117         [p0] = R0;
 118         SSYNC;
 119
 120         /* Initialise UART - when booting from u-boot, the UART is not disabled
 121          * so if we dont initalize here, our serial console gets hosed */
 122         p0.h = hi(BFIN_UART_LCR);
 123         p0.l = lo(BFIN_UART_LCR);
 124         r0 = 0x0(Z);
 125         w[p0] = r0.L;   /* To enable DLL writes */
 126         ssync;
 127
 128         p0.h = hi(BFIN_UART_DLL);
 129         p0.l = lo(BFIN_UART_DLL);
 130         r0 = 0x0(Z);
 131         w[p0] = r0.L;
 132         ssync;
 133
 134         p0.h = hi(BFIN_UART_DLH);
 135         p0.l = lo(BFIN_UART_DLH);
 136         r0 = 0x00(Z);
 137         w[p0] = r0.L;
 138         ssync;
 139
 140         p0.h = hi(BFIN_UART_GCTL);
 141         p0.l = lo(BFIN_UART_GCTL);
 142         r0 = 0x0(Z);
 143         w[p0] = r0.L;   /* To enable UART clock */
 144         ssync;
 145
 146         /* Initialize stack pointer */
 147         sp.l = lo(INITIAL_STACK);
 148         sp.h = hi(INITIAL_STACK);
 149         fp = sp;
 150         usp = sp;
 151
 152 #ifdef CONFIG_EARLY_PRINTK
 153         SP += -12;
 154         call _init_early_exception_vectors;
 155         SP += 12;
 156 #endif
 157
 158         /* Put The Code for PLL Programming and SDRAM Programming in L1 ISRAM */
 159         call _bf53x_relocate_l1_mem;
 160 #if CONFIG_BFIN_KERNEL_CLOCK
 161         call _start_dma_code;
 162 #endif
 163
 164         /* Code for initializing Async memory banks */
 165
 166         p2.h = hi(EBIU_AMBCTL1);
 167         p2.l = lo(EBIU_AMBCTL1);
 168         r0.h = hi(AMBCTL1VAL);
 169         r0.l = lo(AMBCTL1VAL);
 170         [p2] = r0;
 171         ssync;
 172
 173         p2.h = hi(EBIU_AMBCTL0);
 174         p2.l = lo(EBIU_AMBCTL0);
 175         r0.h = hi(AMBCTL0VAL);
 176         r0.l = lo(AMBCTL0VAL);
 177         [p2] = r0;
 178         ssync;
 179
 180         p2.h = hi(EBIU_AMGCTL);
 181         p2.l = lo(EBIU_AMGCTL);
 182         r0 = AMGCTLVAL;
 183         w[p2] = r0;
 184         ssync;
 185
 186         /* This section keeps the processor in supervisor mode
 187          * during kernel boot.  Switches to user mode at end of boot.
 188          * See page 3-9 of Hardware Reference manual for documentation.
 189          */
 190
 191         /* EVT15 = _real_start */
 192
 193         p0.l = lo(EVT15);
 194         p0.h = hi(EVT15);
 195         p1.l = _real_start;
 196         p1.h = _real_start;
 197         [p0] = p1;
 198         csync;
 199
 200         p0.l = lo(IMASK);
 201         p0.h = hi(IMASK);
 202         p1.l = IMASK_IVG15;
 203         p1.h = 0x0;
 204         [p0] = p1;
 205         csync;
 206
 207         raise 15;
 208         p0.l = .LWAIT_HERE;
 209         p0.h = .LWAIT_HERE;
 210         reti = p0;
 211 #if ANOMALY_05000281
 212         nop; nop; nop;
 213 #endif
 214         rti;
 215
 216 .LWAIT_HERE:
 217         jump .LWAIT_HERE;
 218 ENDPROC(__start)
 219
 220 ENTRY(_real_start)
 221         [ -- sp ] = reti;
 222         p0.l = lo(WDOGA_CTL);
 223         p0.h = hi(WDOGA_CTL);
 224         r0 = 0xAD6(z);
 225         w[p0] = r0;     /* watchdog off for now */
 226         ssync;
 227
 228         /* Code update for BSS size == 0
 229          * Zero out the bss region.
 230          */
 231
 232         p1.l = ___bss_start;
 233         p1.h = ___bss_start;
 234         p2.l = ___bss_stop;
 235         p2.h = ___bss_stop;
 236         r0 = 0;
 237         p2 -= p1;
 238         lsetup (.L_clear_bss, .L_clear_bss) lc0 = p2;
 239 .L_clear_bss:
 240         B[p1++] = r0;
 241
 242         /* In case there is a NULL pointer reference
 243          * Zero out region before stext
 244          */
 245
 246         p1.l = 0x0;
 247         p1.h = 0x0;
 248         r0.l = __stext;
 249         r0.h = __stext;
 250         r0 = r0 >> 1;
 251         p2 = r0;
 252         r0 = 0;
 253         lsetup (.L_clear_zero, .L_clear_zero) lc0 = p2;
 254 .L_clear_zero:
 255         W[p1++] = r0;
 256
 257         /* pass the uboot arguments to the global value command line */
 258         R0 = R7;
 259         call _cmdline_init;
 260
 261         p1.l = __rambase;
 262         p1.h = __rambase;
 263         r0.l = __sdata;
 264         r0.h = __sdata;
 265         [p1] = r0;
 266
 267         p1.l = __ramstart;
 268         p1.h = __ramstart;
 269         p3.l = ___bss_stop;
 270         p3.h = ___bss_stop;
 271
 272         r1 = p3;
 273         [p1] = r1;
 274
 275         /*
 276          * load the current thread pointer and stack
 277          */
 278         r1.l = _init_thread_union;
 279         r1.h = _init_thread_union;
 280
 281         r2.l = 0x2000;
 282         r2.h = 0x0000;
 283         r1 = r1 + r2;
 284         sp = r1;
 285         usp = sp;
 286         fp = sp;
 287         jump.l _start_kernel;
 288 ENDPROC(_real_start)
 289
 290 __FINIT
 291
 292 .section .l1.text
 293 #if CONFIG_BFIN_KERNEL_CLOCK
 294 ENTRY(_start_dma_code)
 295         p0.h = hi(SICA_IWR0);
 296         p0.l = lo(SICA_IWR0);
 297         r0.l = 0x1;
 298         [p0] = r0;
 299         SSYNC;
 300
 301         /*
 302          *  Set PLL_CTL
 303          *   - [14:09] = MSEL[5:0] : CLKIN / VCO multiplication factors
 304          *   - [8]     = BYPASS    : BYPASS the PLL, run CLKIN into CCLK/SCLK
 305          *   - [7]     = output delay (add 200ps of delay to mem signals)
 306          *   - [6]     = input delay (add 200ps of input delay to mem signals)
 307          *   - [5]     = PDWN      : 1=All Clocks off
 308          *   - [3]     = STOPCK    : 1=Core Clock off
 309          *   - [1]     = PLL_OFF   : 1=Disable Power to PLL
 310          *   - [0]     = DF        : 1=Pass CLKIN/2 to PLL / 0=Pass CLKIN to PLL
 311          *   all other bits set to zero
 312          */
 313
 314         p0.h = hi(PLL_LOCKCNT);
 315         p0.l = lo(PLL_LOCKCNT);
 316         r0 = 0x300(Z);
 317         w[p0] = r0.l;
 318         ssync;
 319
 320         P2.H = hi(EBIU_SDGCTL);
 321         P2.L = lo(EBIU_SDGCTL);
 322         R0 = [P2];
 323         BITSET (R0, 24);
 324         [P2] = R0;
 325         SSYNC;
 326
 327         r0 = CONFIG_VCO_MULT & 63;       /* Load the VCO multiplier         */
 328         r0 = r0 << 9;                    /* Shift it over,                  */
 329         r1 = CLKIN_HALF;                 /* Do we need to divide CLKIN by 2?*/
 330         r0 = r1 | r0;
 331         r1 = PLL_BYPASS;                 /* Bypass the PLL?                 */
 332         r1 = r1 << 8;                    /* Shift it over                   */
 333         r0 = r1 | r0;                    /* add them all together           */
 334
 335         p0.h = hi(PLL_CTL);
 336         p0.l = lo(PLL_CTL);              /* Load the address                */
 337         cli r2;                          /* Disable interrupts              */
 338         ssync;
 339         w[p0] = r0.l;                    /* Set the value                   */
 340         idle;                            /* Wait for the PLL to stablize    */
 341         sti r2;                          /* Enable interrupts               */
 342
 343 .Lcheck_again:
 344         p0.h = hi(PLL_STAT);
 345         p0.l = lo(PLL_STAT);
 346         R0 = W[P0](Z);
 347         CC = BITTST(R0,5);
 348         if ! CC jump .Lcheck_again;
 349
 350         /* Configure SCLK & CCLK Dividers */
 351         r0 = (CONFIG_CCLK_ACT_DIV | CONFIG_SCLK_DIV);
 352         p0.h = hi(PLL_DIV);
 353         p0.l = lo(PLL_DIV);
 354         w[p0] = r0.l;
 355         ssync;
 356
 357         p0.l = lo(EBIU_SDRRC);
 358         p0.h = hi(EBIU_SDRRC);
 359         r0 = mem_SDRRC;
 360         w[p0] = r0.l;
 361         ssync;
 362
 363         P2.H = hi(EBIU_SDGCTL);
 364         P2.L = lo(EBIU_SDGCTL);
 365         R0 = [P2];
 366         BITCLR (R0, 24);
 367         p0.h = hi(EBIU_SDSTAT);
 368         p0.l = lo(EBIU_SDSTAT);
 369         r2.l = w[p0];
 370         cc = bittst(r2,3);
 371         if !cc jump .Lskip;
 372         NOP;
 373         BITSET (R0, 23);
 374 .Lskip:
 375         [P2] = R0;
 376         SSYNC;
 377
 378         R0.L = lo(mem_SDGCTL);
 379         R0.H = hi(mem_SDGCTL);
 380         R1 = [p2];
 381         R1 = R1 | R0;
 382         [P2] = R1;
 383         SSYNC;
 384
 385         RTS;
 386 ENDPROC(_start_dma_code)
 387 #endif /* CONFIG_BFIN_KERNEL_CLOCK */